Robotrontechnik-Forum

Registrieren || Einloggen || Hilfe/FAQ || Suche || Mitglieder || Home || Statistik || Kalender || Admins

Willkommen Gast!

Robotrontechnik-Forum » Technische Diskussionen » BasiCode-Programme vorgestellt » Themenansicht

Autor

Thread - Seiten: -1-

000
12.11.2023, 16:45 Uhr
ThomasR

Avatar von ThomasR

Eine Frage von FL (033 in "KC85-Farb-Bascoder ergänzen?") brachte mich auf den Gedanken, einen Thread einzurichten, wo in loser Folge beispielhafte BasiCode-Programme vorgestellt werden. Das muss kein Solo-Projekt von mir sein, jeder andere ist auch eingeladen.

Es herrscht leider die Ansicht vor, BC sei simpel und uninteressant. Hej, man sollte es im Kontext der Zeit sehen und nicht von Maßstäben heutiger PS5-Daddler ausgehen! Spiel- oder Knobelspaß kann es auch ohne pompöse Farb- und Sound-Orgien geben. Sicher sind manche Sachen auch dadurch entstanden, dass sich der Autor ein bestimmtes Detail verdeutlichen wollte, dann aber auch den Stolz verspüren wollte, dass seine Kreation über den Äther ausgestrahlt wurde.

Ein paar Sachen vorneweg, vieles wird auf Niederländisch sein. Doch wer Englisch beherrscht und auch bisschen Plattdeutsch versteht, ist zumindest gegenüber Süd-, Ost- und Nordeuropäern, Spaniern und Franzosen im Vorteil: durch den Kontext des jeweiligen Programms und durch Sprachähnlichkeiten kann man doch sehr viel deuten. Aus dem BasiCode-Handbuch https://joyce.de/basicode/download/Man_BC3C.pdf :

Um die riesigen Textkästen zu vermeiden, werde ich auf Quellen verweisen, am häufigsten wohl auf den Programme-Pool der Seite mit dem online-Bascoder (wo das vorgestellte Programm auch sofort getestet werden kann). Hin und wieder wird nach dem Anwählen zunächst ein Fehler und eine Zeilennummer gezeigt werden. Doch wer schon ein paar Jahre mit Basic unterwegs ist, wird kleine Korrekturen leicht ausführen können. Mal fehlt ein abschließendes Gänsefüßchen in einer DATA-Zeile, mal ist es eine andere Kleinigkeit. Wenn kein Fehler mehr da ist, wird das Programm auch starten.

Auch beim KC-Club liegen viele Programme, doch dort nicht in ASCII-Form. Das ist sicher auch beherrschbar.

BasiCode vermeidet Leerzeichen nach Schlüsselwörtern (es gibt die Festlegung, dass die Länge einer Zeile begrenzt ist), das kann manche Basics stören, zu unserem Glück aber nicht das KC-Basic und auch nicht den online-Bascoder.

Leider gibt es (bzw. habe ich) ein kleines Problem mit Programmen, die Arbeit mit Datenbeständen verwenden. Im online-Browser (man kann die Website auch herunterladen und dann von seiner Festplatte auch offline nutzen) wird es irgendwohin gespeichert, aber wie es wieder geladen werden kann, hat sich mir noch nicht erschlossen. Dieses Problem kann natürlich auch vor dem Bildschirm sitzen

, für Hinweise wäre ich dankbar.

Einen Post werde ich jeweils so aufbauen:

eine fettgedruckte Titelzeile mit dem Bereich wie z.B. Geografie, Knobelspiel, Mathematik, Geschicklichkeitsspiel, Astronomie ...

natürlich Name und Download-Link

eine grobe Beschreibung

Screenshots (z.B. auch von Menüs)

ggf. Besonderheiten oder begleitende Informationen

Als Hommage an das Herkunftsland von BasiCode möchte ich mit zwei Geografie-Programmen beginnen.

Geografie

"Topografie" http://robhagemans.github.io/basicode/basicode/Best_of_Basicode_5/30R_Topografie.bc2

Dieses Programm nutzt noch Buchstabengrafik. Die Lage einzelner Städte der Niederlande wird zunächst angezeigt und dann abgefragt.

[img]

[/img]

@FL: Der Autor ist eine Lehrkraft in einer Grundschule (siehe Zeilen 30060-30080), möglich, dass er es im eigenen Unterricht eingesetzt hat.

"Nederland" http://robhagemans.github.io/basicode/basicode/Sammelsurium/DIAGRAMM.E/NEDERLAN.ASC

Ein gleichgelagertes Programm, nun in Pixelgrafik. Die Leistung liegt in der Bereitstellung der Daten für die Koordinatenpaare.

Für Grafiken gilt die Vorgabe, dass das Seitenverhältnis der Zeichenfläche 4:3 betragen soll. So entstehen auf den Computern Bilder mit gleichen Proportionen, die resultierende Feinkörnigkeit hängt jedoch von der Auflösung des konkreten Computers ab. Zur Verdeutlichung habe ich auf dem CPC alle drei möglichen Stufen genutzt. In der Mitte 20-und 40-Spalten-Modus, unten eine Collage aus allen drei Modi, im Mittelbereich der 80-Spalten-Modus. Der eine Übergang läuft genau durch den ausgegebenen Text, der andere ist nicht zu übersehen.

Man erkennt gut, dass BasiCode 40 Spalten als Norm ansieht - bei zwanzig Spalten wird die Schrift unleserlich, die Grafik recht grob. Der hier verwendete CPC kann aber nur in diesem Modus die acht Farben des 3C-Standards darstellen, bei diesem Programm ist es aber nicht relevant. Im "Standard"modus hat er leider nur vier Farben zur Verfügung. Der höchstauflösende Modus hat zu guter Letzt nur zwei Farben, das Bild bleibt auf jeden Fall monochrom

Zwei gleichartige Programme sind

http://robhagemans.github.io/basicode/basicode/Sammelsurium/DIAGRAMM.E/USA.ASC und

http://robhagemans.github.io/basicode/basicode/KC-Club/DDR.bc .
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 12.11.2023 um 20:02 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

001
12.11.2023, 17:38 Uhr
Dirk mit KC-4

Du willst doch jetzt hier nicht wirklich die ganzen Programme von http://robhagemans.github.io/basicode/ vorstellen, oder?

Neue Basicode Programmen, das wäre ok zum vorstellen..
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

002
12.11.2023, 17:47 Uhr
BICa5105

.
Hm...Thomas und Dirk.... Ich glaube ihr beide könntet ein spannendes und witziges Youtube Format ins Lebend rufen. So... Diskussionen und Vorstellungen von DDR Rechentechnik und natürlich dem BasiCode ;-)

Also beide dann vor der Kamera und im direkten Gespräch ;-).
Wie wär's ? Den ersten Abonnenten habt ihr schon ;-)
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

003
12.11.2023, 18:32 Uhr
ThomasR

Avatar von ThomasR

Zitat:

Dirk mit KC-4 schrieb
Du willst doch jetzt hier nicht wirklich die ganzen Programme von http://robhagemans.github.io/basicode/ vorstellen, oder?

Neue Basicode Programmen, das wäre ok zum vorstellen..

Da bist Du ja wieder!

Ein weiteres Mal hast Du nur flüchtig gelesen und übersehen

Zitat:

ThomasR schrieb (...) wo in loser Folge beispielhafte BasiCode-Programme vorgestellt werden.(...)

... und: es werden auch Programme dabei sein, die dort noch nicht aufgenommen sind.

Ansonsten - kann dieser Thread bitte von off-topic-Beiträgen verschont bleiben?

Das hier

Zitat:

ThomasR schrieb (...) zu allem anderen betreffs BasiCode stehe ich Dir gern weiter im Rahmen meiner Erfahrung zur Verfügung (...)

gilt weiterhin, denn dafür ist das Forum da, aber Deine Provokationen werde ich zukünftig einfach ignorieren, um den Rest kümmert sich vielleicht Rüdiger.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 12.11.2023 um 19:10 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

004
12.11.2023, 18:45 Uhr
Dirk mit KC-4

es war keine Provokation, sondern eine Frage, mehr nicht.
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

005
12.11.2023, 20:50 Uhr
ThomasR

Avatar von ThomasR

Geometrie

"Hilbert-Kurve" https://forum.tlienhard.com/phpBB3/download/file.php?id=11873

Es ist ein nicht so altes Programm, der mathematische Hintergrund ist hier beschrieben:

https://joyce.de/basicode/joyce/hilbert.htm .

Solche Programme, die in höchster Präzision und fehlerfrei verzwickte regelmäßige Grafiken erzeugen, begeistern mich von je her.

Hier einmal auf dem ZX81 (Bildschirmgröße 256 x 192 Pixel) ausgeführt, wegen der rekursiven Formel bleibt das Programm klein genug, um in den RAM des nicht so üppig ausgestatteten "Türstoppers" zu passen, denn Grafiktreiber, Grafikdaten und Bascoder verbrauchen schon fast alles.

Das ZX81-Basic lässt nur einen Befehl je Zeile zu und pocht auf die Verwendung von LET bei Variablenzuweisungen, bei wohl allen anderen Computern ist dieser Befehl zwar vorhanden, das Schlüsselwort kann aber weggelassen werden.

Bis zu welcher Verschachtelungstiefe schafft es wohl der KC, bis einfach eine geschlossene Fläche angezeigt wird?

Im Browser-Bascoder gibt es eine Option, das Tempo erheblich zu beschleunigen.

EDIT:

Programmierwettbewerb

Bei der Rekursion verknoten sich die Windungen meines Hirns und es kapituliert - ich bekomme keine Abänderung des Hilbert-Kurve-Programms gebacken, um unter BasiCode Peanokurven https://joyceforum.de/viewtopic.php?p=427#p427 zu programmieren.

Will es einer von Euch probieren? Als Preis winkt dem Ersten (dem ersten, der mit einer funktionierenden Lösung aufwartet, nicht dem ersten Troll, der meint, nicht zielführenden Senf beisteuern zu müssen) ein Papierexemplar des BasiCode-Handbuchs. Das ist kein Scherz - fragt FL, er hat mir schon bei zwei Programmen geholfen, Fehler zu beseitigen und hat zwei Broschüren (wegen der niedrigen Auflagenhöhe große Wertsteigerung prognostiziert) erhalten, isch schwöre, Alter!
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 13.11.2023 um 06:57 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

006
13.11.2023, 10:59 Uhr
ThomasR

Avatar von ThomasR

Knobelspiele

"Othello" http://robhagemans.github.io/basicode/basicode/KC-Club/OTHELLO.bc

Diese Version bietet Wahlmöglichkeiten zur Spielfeldgröße und Spielstärke (siehe links im Bild). Die Spalte muss mit Großbuchstaben angegeben werden. Vermutlich hat es der Autor übersehen, weil es die Standardeinstellung beim KC ist. Es ist, falls es stört, leicht zu korrigieren - z.B. mit der Auswertung von IN statt IN$ (siehe Manual).

Rechts unten ist ein Screenshot aus einer bei mir lokal gespeicherten früheren Version des Bascoders und die linke Seite ist aus der aktuellen Version zusammengestellt.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 13.11.2023 um 13:42 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

007
13.11.2023, 19:19 Uhr
ThomasR

Avatar von ThomasR

Alltagshelfer

"Jahreskalender" http://robhagemans.github.io/basicode/basicode/Wiegand_Fillinger_Basicode_2/05_Kalender.bc2

Dieses Programm lag (mit anderen) auf Kassette dem BRD-Buch zu BasiCode-2 bei.

Man kann einen Monat eines Jahres und die in ihm liegenden festen und beweglichen Feiertage auf dem Bildschirm ausgeben lassen oder das gesamte Jahr mit allen Feiertagen ausdrucken lassen.

Die Ausgabe dieses Programms habe ich (nach etwas Nacharbeit) lange Zeit benutzt, um meinen Schichtplan auszudrucken und in der Familie zu verteilen. So konnten sie sich den Kalender übers Telefon hängen um sich vor einem Anruf vergewissern zu können, ob ich überhaupt zuhause sein würde. Der Schichtrhythmus war nämlich ein wenig knifflig, weil es jede Woche zwei Wechsel von Tag- auf Nachtschicht bzw. von Nacht- auf Tagschicht gab - das konnte kein Nichtbetroffener im Kopf behalten.

Und Spätschichten? Spätschichten gab es nicht. Es handelt sich hier um 12-Stunden-Schichten: 6 bis 18 Uhr oder 18 bis 6 Uhr und das einschließlich der Wochenenden und Feiertage. Jetzt wisst Ihr, wo meine Zeit fürs Hobby verlorenging...

Hätte, hätte, Fahrradlenker. Das Beispiel hier zeigt, wie mein Schichtplan in meinem letzten vollen Arbeitsjahr 2027 ausgesehen hätte,

wenn die Chefs dieses Schema durchgedrückt hätten, was aber glücklicherweise zweimal am Betriebsrat bzw. der Abstimmung der Betroffenen gescheitert ist und

wenn die Rente ab 70 schon durchgesetzt wäre.

Achtet auf die Details: ein Schichtblock hätte immer mit Tagschicht begonnen und immer mit Nachtschicht geendet: sechs mal pro vier Kalenderwochen. Bei unserem tatsächlichen System war es hälftig auf beide Möglichkeiten aufgeteilt und das war stressig genug. Es hätte in vier Wochen ein kurzes Wochenende (48 Stunden) und ein langes Wochenende (96 Stunden) und zwei Arbeitswochenenden gegeben.

Das Programm lief wieder auf einem emulierten CPC. Dieser französische Emulator ist noch in Entwicklung. Der Programmierer hat das Ziel, dass er alle Demos (manche nutzen viele Tricks, das ist der Stolz dieser Szene) korrekt wiedergibt.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 13.11.2023 um 19:43 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

008
14.11.2023, 21:03 Uhr
ThomasR

Avatar von ThomasR

Inzwischen ist wohl deutlich geworden: BasiCode ist nichts Kompliziertes, Außergewöhnliches. BasiCode ist einfach Basic mit Vor- und Nachteilen, wer schon mit Basic gearbeitet hat, kann es auch mit BasiCode. Es hat sogar inzwischen den "Schrecken" verloren, dass man mit Kassetten jonglieren muss - heute stehen genug andere Übertragungswege zur Verfügung. In Zeiten von DeepL ist auch die niederländische Sprache kaum noch eine Barriere.

Ein Nachteil ist, dass der Befehlsvorrat eingeschränkt ist (kein DEEK, DOKE, VPEEK, VPOKE, WINDOW ...), der Vorteil die unkomplizierte Übertragbarkeit auf Computer anderer Hersteller, außerdem die kaum eingeschränkten Nutzungsrechte. Ein Pool beachtlicher Größe teilweise exzellenter Programme wartet auf Entdeckung und Nutzung.

Alltagshelfer

"Help V 1.3" http://robhagemans.github.io/basicode/basicode/KC-Club/HELP.bc]

Das Programm bietet einige nützliche Funktionen auch für Programmierer und Elektronikbastler. Ja, heute hat man das alles in Apps auf seinem Smartphone, aber damals stand 1991 auf dem Kalender. Und: auch dieses Programm kann man auf dem Smartphone nutzen - um das zu zeigen, seht Ihr hier Handy-Screenshots des schon oft erwähnten Browser-Bascoders http://robhagemans.github.io/basicode/ . Die Funktionen werden in dem separatem Programm "Help-Instruktionen" http://robhagemans.github.io/basicode/basicode/KC-Club/HELPDOK.bc erläutert.

In den Screenshots sind rechts verschiedene Menüs des Bascoders zu sehen. Ganz unten steht "Presets", dort kann die Erscheinungsweise beispielsweise des Amstrad CPC eingestellt werden, aber das betrifft nur den Schriftfont und die Farben von Vorder- und Hintergrund - es wird keine Emulation eines Amstrad ausgeführt! Unter "Font" kann die Schriftart des Lieblingscomputers eingestellt werden und unter "Size" kann das Feeling des KC eingestellt werden (Spalten- und Zeilenzahl). Die Geschwindigkeit kann unter "Speed" bis 100000 Takte je Sekunde hochgetrieben werden.

Hier lässt sich ein Beispiel demonstrieren, wie leicht eine evtl. erforderliche Korrektur ist. Das Programm wird mit der Fehlermeldung "Division by Zero in 6010" abbrechen, oder wie der betreffende Fehler auf dem gerade verwendeten Computer formuliert ist. Dem Autor ist der kleine Lapsus unterlaufen, LN statt LOG zu schreiben (In BasiCode arbeitet LOG mit der Basis der Eulerschen Zahl und LN zählt zu den nicht erlaubten Befehlen). Unter dem Reiter "Listing" kann zur betreffenden Zeile gescrollt werden, um den Fehler zu korrigieren. Dann einfach ins Ausgabefenster tippen/klicken und das korrigierte Programm startet wieder.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 15.11.2023 um 16:31 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

009
14.11.2023, 22:39 Uhr
Dirk mit KC-4

Hallo Thomas, da du ja hier in deinem Basicode vertieft bist.. wollt ich dir auch hier antworten. Alles gut :-)

In dem Softwarepacket fand ich übrigens im Z 1013 Ordner auch Basicode Dateien, alles .z80 Dateien. Ich weiß aber nicht was da ist, ich hab so einen Z 1013 nicht.
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

010
15.11.2023, 19:54 Uhr
ThomasR

Avatar von ThomasR

Grafik

"Gelddame" und "BC-Girl" https://joyce.de/basicode/download/BC-BILDER-ASC.zip

Am Ende des BasiCode-Programms steht oft der Ausstrahlungszeitpunkt der niederländischen oder Berliner Radiostation. Das ist hier nicht der Fall, weil das Programm zu spät fertiggestellt wurde, auch DS Kultur hatte als letzter Sender Abschied von BasiCode genommen.

Diese Programme erreichten mich auch erst vor ein paar Jahren, bei Rob Hagemans sind sie nicht zu finden. Der Chef des plus/4-Clubs schickte sie mir auf einer Diskette. Vielleicht wollte sich der Autor als Banknotenfälscher betätigen? Aber das Equipment war bei weitem noch nicht ausgereift genug.

Vielleicht ist er ja stattdessen mit dem Verkauf seiner Scans reich geworden?

Die beiden Programme sind in der Zip-Datei enthalten. In GELDDAME.ASC ist Zeile 1010 wie oben gezeigt zu ändern - es sei denn, Ihr nutzt das Programm auf dem Amstrad PCW.

Das Porträt der jungen Dame verstopfte seinerzeit die Boxen der Mailserver. Die Programme liefen diesmal unter BBC Basic for Windows, die kostenlose Evaluationsversion ist zum Glück ausreichend. Den passenden Bascoder findet Ihr in 003 von "KC85-Farb-Bascoder ergänzen?"
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 15.11.2023 um 22:00 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

011
15.11.2023, 21:38 Uhr
ThomasR

Avatar von ThomasR

Grafik / Sound - Demo

"Freundschaft" http://robhagemans.github.io/basicode/basicode/KC-Club/FREUNDSF.bc

Dieses Programm (und sein Erläuterungsprogramm "Faxicode" http://robhagemans.github.io/basicode/basicode/KC-Club/FAXICODE.bc) versetzt uns in das Jahr 1991 zurück. Es entstand in Zusammenarbeit eines Computerfreundes (Grafik) aus dem Eichsfeld (Thüringen) und eines aus den Niederlanden (Sound).

Es gab noch kein Internet für Otto Normalverbraucher und die Nutzung eines Faxgeräts war kostenintensiv. Die beiden hatten die Idee für einen preiswerteren Weg, die Zwischenstände ihres Projekts untereinander auszutauschen:

Auch wenn es hier danach aussieht, ist es kein Farbprogramm. Die roten und grünen Striche entstehen im Emulationsprogramm. Mag das nicht perfekt sein, bietet der Emulator aber den Vorteil, ein ASCII-File einfach per Mausklick aus der Windows-Zwischenablage in den "Atari"-RAM zu übertragen, siehe Beginn des Listings nach der Bereitschaftsmeldung des Bascoders von Andreas Graf.

Sehr viel Arbeit steckt in der Erstellung der Daten für den Sound- und die Grafik.

Die Textausgabe ist auf dem 8-bit-Atari etwas zu breit für die Rahmen der Grafikausgabe - es kommt öfter vor, dass ein Programm erst einmal für den eigenen Computer etwas Nacharbeit erfordert, wenigstens ist dergleichen in Basic weniger knifflig als in Maschinencode.

--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 15.11.2023 um 22:05 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

012
16.11.2023, 21:16 Uhr
ThomasR

Avatar von ThomasR

Grafik / Sound - Demo

"Notenbalk" http://robhagemans.github.io/basicode/basicode/Sammelsurium/MUSIK/NOTENBAN.ASC

Dieses Programm zählt zu meinen Favoriten. Es nutzt neue Möglichkeiten der Version 3 von BC3: Grafik, Sound und Dateiarbeit, ist also recht anspruchsvoll.

Hier läuft es unter GW-Basic (das auch in Basicode@DFend genutzt wird), dort ist der Sound angenehmer als das gewöhnliche Computergepiepse.

Man erkennt an der kleinen Schrift, dass im Grafkbetrieb der 80-Spalten-Modus genutzt wird - die Auflösung ist feiner. Im Textmodus, den damaligen Verhältnissen entsprechend 40 Buchstaben je Zeile, so hatten es die meisten Heimcomputer,

Leider liegen bei Rob Hagemans nicht die drei Beispielsdateien (Vielleicht, weil er dieses Feature noch nicht programmiert hat? Oder ich habe die erforderliche Bedienung noch nicht begriffen, kann ebenso sein.), ich drucke sie einfach hier mit ab.

Quellcode:

VIER WEVERKENS
b64
20 4M
60044
50 4
65044
01 4
69044
50 4
65044
40 4
64044
60 4
67044
40 4M
64044
30 4
62044
50 4
65044
30 4
62044
20 2
60084
30 8
62024
40 8M
64024
50 4
65044
50 4
65044
50 4
65044
30 4
62044
30 4
62044
60 4M
67044
40 2.
64124
50 2
65084
20 4
60044
50 4
65044
01 4
69044
50 4
65044
40 4
64044
60 4
67044
40 4M
64044
30 4
62044
50 4
65044
30 4
62044
20 2
60084
20 4M
60044
50 4
65044
50 4
65044
50 4
65044
30 4
62044
30 4
62044
60 4M
67044
40 2.
64124
50 2
65084
20 4
60044
11 4
70044
60 4
67044
60 8
67024
60 8
67024
01 4
69044
50 4
65044
20 4M
60044
50 2
65084
21 4
72042
01 2
69082
60 8
67024
01 8M
69024
11 4
70044
60 4
67044
60 8
67024
60 8
67024
01 4
69044
50 4
65044
20 4M
60044
50 2
65084
21 4
72042
01 2
69082
20 4
60044
30 4
62044
30 4
62044
30 4
62044
60 4
67044
60 4
67044
60 4M
67044
40 2.
64124
50 2
65084
21 4M
72042
51 2
77082
M
M

ZIE GINDS...
#64








30 4 
62044
M    

60 4 
67044


60 4 
67044


11 4 
71044


01 4 
69044


01 4 
69044


21 4 
72044
M    

50 4 
66044
50 4 
66044
01 4 
69044
60 2 
67084


30 4 
62044


60 4 
67044


60 4 
67044


11 4 
71044


01 8 
69024
01 8 
69024
01 4 
69044


21 4 
72044
M    

50 4 
66044


50 4 
66044


01 4 
69044


60 2 
67084






31 4 
74044


01 4 
69044


01 4 
69044


31 4 
74044


11 4 
71044


11 4 
71044


31 4 
74044
M    

21 4 
72044


21 4 
72044


11 4 
71044


01 2 
69084






30 4 
62044


60 4 
67044


60 8 
67024
01 8 
69024
11 8 
71024
21 8 
72024
31 4 
74044


11 4 
71044


60 4 
67044
M    

21 4 
72044


01 4 
69044


50 4 
66044


60 2 
67084






M 
M 

NACHT IN MOSKOU
b44


30 4
62044
50 4
65044
01 4
69044
50 4M
65044
60 2
67084


50 4
65044
40 4M
64044
01 2
69084


60 2
67084
M

30 2
62084


20 2
60084
M

50 4
65044
01 4
69044
21 4
72044
21 4M
72044
31 2
74084
21 4
72044
11 4
70044


01 1
69164
M

11#2
71084


21#2
73084
M

41 4
76044
31 4
74044
01 2
69124
M

01+4

50 4
65044
40 4
64044
30 4M
62044
01 4
69044
60 4
67044
11 2
70164
M

11+2



21 4
72044
11 4
70044




01 2
69084


60 4
67044
50 4M
65044
01 2
69084


60 2
67084
M

30 2
62084


01 2
69084
M

11#2
71084


21#2
73084
M

41 4
76044
31 4
74044
01 2M
69124
01+4

50 4
65044
40 4
64044
30 4
62044


01 4
69044
60 4
67044
11 2
70164
M

11+2



21 4
72044
11 4M
70044
01 2
69084


60 4
67044
50 4M
65044
01 2
69084




60 2
67084


M

30 1
62164






M
M

Übrigens, das Manual

ist immer noch nicht vergeben: noch kein Teilnehmer hat die Wettbewerbsaufgabe (am Ende von 005) richtig gelöst.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 16.11.2023 um 22:35 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

013
17.11.2023, 18:47 Uhr
ThomasR

Avatar von ThomasR

Grafik-Demo

"Ellipsen Fantasie" in https://joyce.de/basicode/download/BC_togo.zip

Auch dieses Programm von 1992 gelangte noch nicht auf Rob Hagemans' Seite. Ich fand es auf kc85emu.de im Basicode@DFend-Paket. Es ist eine kleine grafische Spielerei, die den Amiga völlig unterfordert, aber das trifft ja bei diesem Computer für wohl jedes BasiCode-Programm zu. Etwas anders sieht es beim bereits vorgestellten Programm (008 in "KC85-Farb-Bascoder ergänzen?") aus, in dem man mit (niederländischen...) LOGO-Befehlen einfache Grafiken zeichnen kann, zumindest für den Speicherbedarf. In 016 steht, wo es heruntergeladen werden kann. Das Programm braucht schon einmal mehr RAM für die Basiczeilen und die zu reservierenden Variablen, als den meisten Heimcomputern zur Verfügung steht.

Programmiert man "Ellipsen Fantasie" ein wenig um, hat man einen netten kleinen Bildschirmschoner.

Man kann es (Abwärtskompabilität) auch auf monochromen Computern wie dem Amstrad PCW nutzen, dort werden im Bascoder die zuständigen Variablen CC(0) und CC(1) halt erst gar nicht ausgewertet.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 17.11.2023 um 19:10 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

014
17.11.2023, 23:21 Uhr
ThomasR

Avatar von ThomasR

Mathematik

"FKT3D" http://robhagemans.github.io/basicode/basicode/KC-Club/FKT3D.bc

Perspektivische Darstellungen von Funktionen zweier Veränderlicher haben mich schon immer fasziniert. Im Berliner BasiCode-Buch ist ein Programm dafür abgedruckt.

Es braucht eine kleine Korrektur. In Zeile 1140 wird der Variablen ZE der Default-Wert 1 zugewiesen. Bis zu dieser Höhe werden die Graphen auch nur gezeichnet, weil in Zeile 1390 der gewünschte Wert für die maximale Höhe erfragt, aber danach nicht ausgewertet wird. Das ist durch das Einfügen der Zeile

1405 ZE=VAL(A$)

leicht zu beheben.

Die zu zeichnende Funktion wird in den Zeilen 1020 und 1030 eingetragen, Prof. Völz (der Autor) schlägt als weitere attraktive Zeilenpaare vor:

Halbkugel Z=36-X*X-Y*Y
Z=SQR(SGN(SGN(Z)+1))*Z

Spaltfunktion Z=X*X+Y*Y
Z=COS(Z)/(Z+1)

Kantenfunktion Z=ABS(X*Y)
Z=COS(Z)/(Z+1)

oder einfach nur die Zeile

Sattelkurve Z=X*X-Y*Y .

Hier kann der Amstrad PCW seine Stärke voll ausspielen, ihm steht eine Zeichenfläche von 720 * 512 Pixeln zur Verfügung, das ist mehr, als zu seiner Zeit die DOS-Computer hatten.

Wenn die gewählten Begrenzungen noch nicht passen - einfach abbrechen und mit GOTO 1180 neu in ihre Abfrage gehen, dabei werden die bisher geltenden Werte zur Orientierung angezeigt.

Wenn der "tragende Kasten" fertig gezeichnet ist, ist das Zeichnen beendet. Nach einem beliebigem Tastendruck werden noch links oben die Grenzen der drei Richtungen angezeigt, nach einem weiterem Tastendruck kehrt das Programm in den Textmodus zurück.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 18.11.2023 um 07:10 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

015
18.11.2023, 13:08 Uhr
ThomasR

Avatar von ThomasR

Erdkunde

"Aardbol in dag en nacht" http://robhagemans.github.io/basicode/basicode/Verzamelcassette_5/B11_Aardbol_in_dag_en_nacht.bc3

Sehr viele Programme finden sich für den Bereich Geografie. Daraus habe ich eins gewählt, das für einen bestimmten Tag und eine bestimmte Uhrzeit anzeigt, wo auf der Erdkugel es hell und wo es dunkel ist.

Hut ab vor dem Programmierer, der die vielen Daten erstellt hat und die Formeln im Griff hat, um das Bild der Erde (in zwei Darstellungsarten) in die richtige Position zu drehen und richtig zu beleuchten!

Hier läuft es auf einem emulierten Atari ST im 80-Spalten-Modus, um eine möglichst feine Auflösung nutzen zu können.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 18.11.2023 um 13:08 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

016
19.11.2023, 12:54 Uhr
ThomasR

Avatar von ThomasR

Mit dem folgenden Programm möchte ich meine kleine Beispielsammlung vorerst beenden.

Nebenbei habt ihr auch das Arbeiten des "Computer-Esperantos" auf diversen unterschiedlichen Computern kennengelernt.

Wer möchte, kann hier gern weitere Programme vorstellen, das schrieb ich ja auch schon ganz am Anfang.

Auch der Programmierwettbewerb aus 005 ist noch nicht geschlossen. Wer zeigt die erste funktionierende Lösung?

Grafik - Demo

"Animatie 2.0" in http://www.nostalgia8.nl/logo/bc3logo.zip

Dieses Programm stammt aus dem Paket, in dem auch BC3-LOGO enthalten ist (siehe 008 in "KC85-Farb-Bascoder ergänzen" und hier, unten im Bild von 013). Es zeigt Animationen an, die mit dem auch dort enthaltenen Programm "Rundflug" erzeugt und abgespeichert werden können. Es läuft hier unter dem Bascoder zum PC-Basic https://robhagemans.github.io/pcbasic/. PC-Basic wiederum ist ein GW-Basic-Emulator für aktuelles Windows.

Mit den vorbereiteten Beispieldateien aus dem Paket können folgende "Filmchen" ablaufen:

ein Würfel, der sich dreht und ab und zu die Farbe ändert,

eine sich drehende 3 1/2-Zoll-Diskette und

ein sich drehendes Viereck, um das sechs Striche herumtanzen.

Auch dieses Programm kann als eine Art Bildschirmschoner im Look der 80er genutzt werden

--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 19.11.2023 um 13:23 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

017
19.11.2023, 16:47 Uhr
Hojoe

Zitat:

ThomasR schrieb
Auch der Programmierwettbewerb aus 005 ist noch nicht geschlossen. Wer zeigt die erste funktionierende Lösung?[/color]

Da dir offensichtlich etwas daran liegt, hier eine Lösung im KC85/4 Basic für die Peano-Kurven. Es ist einfach gehalten, damit sollte eine Portierung nach BasiCode nicht allzu kompliziert sein.
Ich habe das bisher nur im JKCEmu getestet, bin aber sehr optimistisch, dass es auch auf echter Hardware funktioniert :-)

Quellcode:


100 ! Peano-Kurven: 
101 ! https://de.wikipedia.org/wiki/Peano-Kurve

1001 dim Stack(9*8)
1002 mx=200
1010 cls
1011 Print "Peano Kurfe"
1012 Print "Verschachtelungstiefe (0-5):"
1013 Print "  (0 - Ende)"
1014 Input t
1015 if t < 1 goto 1099
1016 if t > 5 goto 1010

1020 sp=0:ST(0)=t
1021 gosub 10000
1031 ts = mx/(3^t-1)
1035 tx=320/2-mx/2:
1036 ty=10

1050 gosub 1100
1051 print "weiter mit <SPACE>"
1052 k$=inkey$:if k$<>" " goto 1052
1059 goto 1010
1099 end

1100 ! P -> PFQFP-F- SFRFS+F+ PFQFP
1101 n=st(sp)
1102 if n=0 goto 1199
1103 n=n-1
1104 sp=sp+1:st(sp)=n

1120 gosub 1100  !P
1121 gosub 10030 !F
1122 gosub 1200  !Q
1123 gosub 10030 !F
1124 gosub 1100  !P
1125 gosub 10020 !-
1126 gosub 10030 !F
1127 gosub 10020 !-

1128 gosub 1400  !S
1129 gosub 10030 !F
1130 gosub 1300  !R
1131 gosub 10030 !F
1132 gosub 1400  !S
1133 gosub 10010 !+
1134 gosub 10030 !F
1135 gosub 10010 !+

1136 gosub 1100  !P
1137 gosub 10030 !F
1138 gosub 1200  !Q
1139 gosub 10030 !F
1140 gosub 1100  !P
1190 sp=sp-1
1199 return

1200 ! Q -> QFPFQ+F+ RFSFR-F- QFPFQ
1201 n=st(sp)
1202 if n=0 goto 1299
1203 n=n-1
1204 sp=sp+1:st(sp)=n

1220 gosub 1200  !Q
1221 gosub 10030 !F
1222 gosub 1100  !P
1223 gosub 10030 !F
1224 gosub 1200  !Q
1225 gosub 10010 !+
1226 gosub 10030 !F
1227 gosub 10010 !+

1228 gosub 1300  !R
1229 gosub 10030 !F
1230 gosub 1400  !S
1231 gosub 10030 !F
1232 gosub 1300  !R
1233 gosub 10020 !-
1234 gosub 10030 !F
1235 gosub 10020 !-

1236 gosub 1200  !Q
1237 gosub 10030 !F
1238 gosub 1100  !P
1239 gosub 10030 !F
1240 gosub 1200  !Q

1290 sp=sp-1
1299 return

1300 ! R -> RFSFR-F- QFPFQ+F+ RFSFR
1301 n=st(sp)
1302 if n=0 goto 1399
1303 n=n-1
1304 sp=sp+1:st(sp)=n

1320 gosub 1300  !R
1321 gosub 10030 !F
1322 gosub 1400  !S
1323 gosub 10030 !F
1324 gosub 1300  !R
1325 gosub 10020 !-
1326 gosub 10030 !F
1327 gosub 10020 !-

1328 gosub 1200  !Q
1329 gosub 10030 !F
1330 gosub 1100  !P
1331 gosub 10030 !F
1332 gosub 1200  !Q
1333 gosub 10010 !+
1334 gosub 10030 !F
1335 gosub 10010 !+

1336 gosub 1300  !R
1337 gosub 10030 !F
1338 gosub 1400  !S
1339 gosub 10030 !F
1340 gosub 1300  !R

1390 sp=sp-1
1399 return

1400 ! S -> SFRFS+F+ PFQFP-F- SFRFS
1401 n=st(sp)
1402 if n=0 goto 1499
1403 n=n-1
1404 sp=sp+1:st(sp)=n

1420 gosub 1400  !S
1421 gosub 10030 !F
1422 gosub 1300  !R
1423 gosub 10030 !F
1424 gosub 1400  !S
1425 gosub 10010 !+
1426 gosub 10030 !F
1427 gosub 10010 !+

1428 gosub 1100  !P
1429 gosub 10030 !F
1430 gosub 1200  !Q
1431 gosub 10030 !F
1432 gosub 1100  !P
1433 gosub 10020 !-
1434 gosub 10030 !F
1435 gosub 10020 !-

1436 gosub 1400  !S
1437 gosub 10030 !F
1438 gosub 1300  !R
1439 gosub 10030 !F
1440 gosub 1400  !S

1490 sp=sp-1
1499 return

10000 ! Turtle Init
10001 !  ts -> Turte step
10002 !  tx -> X Koordinate der Turtle
10003 !  ty -> Y Koordinate der Turtle
10004 !  tr -> Richtung der Turtle
10005 !    0-Up 1-Left 2-Down 3-Right
10006 ts=8:tx=100:ty=100:tr=0:tf=7
10007 return

10010 ! Turtle Left (+)
10011 tr = tr+1
10012 if tr > 3 then tr = 0
10013 return

10020 ! Turtle Right (-)
10021 tr = tr-1
10022 if tr < 0 then tr = 3
10023 return

10030 ! Turtle Forward (F)
10031 ta = tx:tb=ty
10032 if tr=0 then tb=ty+ts:goto10036
10033 if tr=1 then ta=tx-ts:goto10036
10034 if tr=2 then tb=ty-ts:goto10036
10035 if tr=3 then ta=tx+ts:goto10036
10036 line tx,ty,ta,tb,tf
10037 tx=ta:ty=tb
10038 return
10099 ! ende Turtle

Holger

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

018
19.11.2023, 20:38 Uhr
ThomasR

Avatar von ThomasR

Programmierwettbewerb beendet

*** The winner is ... ***

Zitat:

Hojoe schrieb: Da dir offensichtlich etwas daran liegt, hier eine Lösung im KC85/4 Basic für die Peano-Kurven. Es ist einfach gehalten, damit sollte eine Portierung nach BasiCode nicht allzu kompliziert sein. (...)

Holger

Bravo, Holger! Der Preis gehört Dir. Verrate mir per PN eine Anschrift, wo ich ihn hinsenden soll und der Brief geht schon morgen Vormittag auf die Reise.

Gratulation!

Thomas
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 19.11.2023 um 20:45 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

019
22.11.2023, 20:19 Uhr
Hojoe

Hallo,

nachdem ich mir das BasiCode Handbuch angeschaut habe, hier die BasiCode Variante

Quellcode:


1000 LET A=200:GOTO 20:REM Peano-Kurven
1001 REM https://de.wikipedia.org/wiki/Peano-Kurve
1010 REM go ...

1020 GOSUB 100
1022 PRINT "Peano Kurve"
1023 PRINT "Verschachtelungstiefe (0-5):"
1024 PRINT "  (0 - Ende)"
1025 GOSUB 210
1026 IF IN < 49 GOTO 950
1027 IF IN > 53 GOTO 1020
1028 LET T=IN-48

1029 REM N - Rekursions-/ Verschachtelungstiefe
1030 LET N=T
1031 LET TR=0
1032 LET TS = 0.8/(3^T-1)
1034 GOSUB 600
1035 LET HO=0.1
1036 LET VE=0.9
1037 LET CN=1:GOSUB 620
1038 LET CN=0

1049 REM Hier beginnt die Arbeit
1050 GOSUB 1100

1060 LET HO=0:LET VE=0:LET CN=1
1061 GOSUB 620
1062 LET CN=0
1063 LET SR$="weiter mit <SPACE>"
1064 GOSUB 650 
1065 GOSUB 210
1066 IF IN<> 32 GOTO 1065
1069 GOTO 1020

1100 REM P -> PFQFP-F- SFRFS+F+ PFQFP
1102 IF N=0 GOTO 1199
1103 LET N=N-1
1120 GOSUB 1100  :REM P
1121 GOSUB 10030 :REM F
1122 GOSUB 1200  :REM Q
1123 GOSUB 10030 :REM F
1124 GOSUB 1100  :REM P
1125 GOSUB 10020 :REM -
1126 GOSUB 10030 :REM F
1127 GOSUB 10020 :REM -

1128 GOSUB 1400  :REM S
1129 GOSUB 10030 :REM F
1130 GOSUB 1300  :REM R
1131 GOSUB 10030 :REM F
1132 GOSUB 1400  :REM S
1133 GOSUB 10010 :REM +
1134 GOSUB 10030 :REM F
1135 GOSUB 10010 :REM +

1136 GOSUB 1100  :REM P
1137 GOSUB 10030 :REM F
1138 GOSUB 1200  :REM Q
1139 GOSUB 10030 :REM F
1140 GOSUB 1100  :REM P
1190 LET N=N+1
1199 RETURN

1200 REM Q -> QFPFQ+F+ RFSFR-F- QFPFQ
1202 IF N=0 GOTO 1299
1203 LET N=N-1
1220 GOSUB 1200  :REM Q
1221 GOSUB 10030 :REM F
1222 GOSUB 1100  :REM P
1223 GOSUB 10030 :REM F
1224 GOSUB 1200  :REM Q
1225 GOSUB 10010 :REM +
1226 GOSUB 10030 :REM F
1227 GOSUB 10010 :REM +

1228 GOSUB 1300  :REM R
1229 GOSUB 10030 :REM F
1230 GOSUB 1400  :REM S
1231 GOSUB 10030 :REM F
1232 GOSUB 1300  :REM R
1233 GOSUB 10020 :REM -
1234 GOSUB 10030 :REM F
1235 GOSUB 10020 :REM -

1236 GOSUB 1200  :REM Q
1237 GOSUB 10030 :REM F
1238 GOSUB 1100  :REM P
1239 GOSUB 10030 :REM F
1240 GOSUB 1200  :REM Q
1290 LET N=N+1
1299 RETURN

1300 REM R -> RFSFR-F- QFPFQ+F+ RFSFR
1302 IF N=0 GOTO 1399
1303 LET N=N-1
1320 GOSUB 1300  :REM R
1321 GOSUB 10030 :REM F
1322 GOSUB 1400  :REM S
1323 GOSUB 10030 :REM F
1324 GOSUB 1300  :REM R
1325 GOSUB 10020 :REM -
1326 GOSUB 10030 :REM F
1327 GOSUB 10020 :REM -

1328 GOSUB 1200  :REM Q
1329 GOSUB 10030 :REM F
1330 GOSUB 1100  :REM P
1331 GOSUB 10030 :REM F
1332 GOSUB 1200  :REM Q
1333 GOSUB 10010 :REM +
1334 GOSUB 10030 :REM F
1335 GOSUB 10010 :REM +

1336 GOSUB 1300  :REM R
1337 GOSUB 10030 :REM F
1338 GOSUB 1400  :REM S
1339 GOSUB 10030 :REM F
1340 GOSUB 1300  :REM R
1390 LET N=N+1
1399 RETURN

1400 REM S -> SFRFS+F+ PFQFP-F- SFRFS
1402 IF N=0 GOTO 1499
1403 LET N=N-1
1420 GOSUB 1400  :REM S
1421 GOSUB 10030 :REM F
1422 GOSUB 1300  :REM R
1423 GOSUB 10030 :REM F
1424 GOSUB 1400  :REM S
1425 GOSUB 10010 :REM +
1426 GOSUB 10030 :REM F
1427 GOSUB 10010 :REM +

1428 GOSUB 1100  :REM P
1429 GOSUB 10030 :REM F
1430 GOSUB 1200  :REM Q
1431 GOSUB 10030 :REM F
1432 GOSUB 1100  :REM P
1433 GOSUB 10020 :REM -
1434 GOSUB 10030 :REM F
1435 GOSUB 10020 :REM -

1436 GOSUB 1400  :REM S
1437 GOSUB 10030 :REM F
1438 GOSUB 1300  :REM R
1439 GOSUB 10030 :REM F
1440 GOSUB 1400  :REM S
1490 LET N=N+1
1499 RETURN

10000 REM TR - Turtle Richtung
10001 REM      0-Up 1-Left 2-Down 3-Right
10002 REM TS - Turtle Schrittweite

10010 REM Turtle Left (+)
10011 LET TR = TR+1
10012 IF TR > 3 THEN LET TR = 0
10013 RETURN

10020 REM Turtle Right (-)
10021 LET TR = TR-1
10022 IF TR < 0 THEN LET TR = 3
10023 RETURN

10030 REM Turtle Forward (F)
10032 IF TR=0 THEN LET VE=VE-TS:GOTO10037
10033 IF TR=1 THEN LET HO=HO-TS:GOTO10037
10034 IF TR=2 THEN LET VE=VE+TS:GOTO10037
10035 IF TR=3 THEN LET HO=HO+TS:GOTO10037
10037 GOSUB 630
10039 RETURN

Holger

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

020
22.11.2023, 23:42 Uhr
ThomasR

Avatar von ThomasR

Zitat:

Hojoe schrieb
Hallo,

nachdem ich mir das BasiCode Handbuch angeschaut habe, hier die BasiCode Variante (...)

Super, Holger!

Nun läuft es auf jedem BasiCode-fähigen Rechner und am Handy habe ich es gleich erfolgreich unter dem Online-Bascoder getestet.

Dort läuft es rasend schnell (und kann unter Settings noch schneller eingestellt werden).

Unter Settings habe ich auch die Zeilen- und Spaltenzahl vergrößert, so wird sogar Verschachtelungstiefe 5 noch ohne Linienberührungen dargestellt.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 23.11.2023 um 00:27 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

021
29.12.2023, 10:46 Uhr
ThomasR

Avatar von ThomasR

Bascoder für Java / XMAS2021

Werft einmal einen Blick in https://joyceforum.de/viewtopic.php?f=5&t=102, dort tut sich etwas Interessantes!

Michael stellt ein Github-Projekt vor: er ist dabei, einen Bascoder für Java zu schreiben. Das bedeutet, BasiCode-Programme können in verschiedenen Betriebssystemen unmittelbar ausgeführt werden - also ohne erst irgendein Basic oder die Emulation eines Computers aufrufen zu müssen.

"Nebenbei" fiel dabei ein kleines Programm ab, das einen netten Weihnachtsgruß darstellt.

Auf Tastendruck wird das Bäumchen jeweils neu geschmückt, beendet wird mit "E".

Quellcode:

1000 GOTO 20: REM XMAS2021
1010 KU=6:DIM CC(2):CC(0)=4:CC(1)=0:GOSUB 600
1015 VE=0:HO=0.5:CC(0)=6:SR$="*":GOSUB 650
1020 FOR PA=1 TO 20
1025 IF PA>16 THEN 1062
1030 FOR PB=0 TO (PA/2)
1031 VE=(PA/26):HO=((16+PB)/32):CC(0)=4 
1034 GOSUB 260:REM RND Ergebnis in RV
1035 IF RV<0.9 THEN 1041
1036 SR$="O":GOSUB 20000:CC(0)=KU:GOSUB 650:CC(0)=4
1037 GOTO 1042
1041 SR$="#":GOSUB 650
1042 VE=(PA/26):HO=((16-PB)/32):IF PB=0 THEN 1060
1043 GOSUB 260:IF RV<0.9 THEN 1050
1045 SR$="O":GOSUB 20000:CC(0)=KU:GOSUB 650:CC(0)=4
1046 GOTO 1060
1050 IF PB<>0 THEN SR$="#":GOSUB 650
1060 NEXT PB
1061 GOTO 1070
1062 VE=(PA/26):HO=(15/32):SR$="####":GOSUB 650
1070 NEXT PA
1080 VE=(21/26):HO=(8/26):CC(0)=7:SR$="Frohe Weihnachten":GOSUB 650
1090 GOSUB 210:REM Warten auf Tastendruck = <E>nde
1100 IF IN<>69 THEN GOSUB 600:GOTO 1015
1999 GOSUB 100:GOTO 950
20000 KU=KU-2*(KU=1)-2*(KU=3)-2*(KU=5)+5*(KU=7)-4*(KU=2)+5*(KU=6):RETURN
30000 REM evtl. DIM in 1010 entfernen (in manchen Bascodern bereits enthalten)
30010 REM
30020 REM 20000 ggf. anpassen, wenn logisch wahr nicht den Wert -1 hat
30030 REM
32000 REM nach einer Idee von John Kennedy fuer ZX81
32010 REM
32020 REM angepasst fuer BasiCode von Paul Veltjens JOYCE-User-AG e.V.
32030 REM
32040 REM Ergaenzungen fuer Farb-Betrieb Thomas Rademacher JOYCE-User-AG e.V.
32050 REM

Zum großen Teil läuft der Bascoder schon (und ist der schnellste, den ich je gesehen habe!), um ihn weiter zu perfektionieren, seid auch Ihr herzlich eingeladen!
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 29.12.2023 um 11:09 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

022
06.03.2024, 15:55 Uhr
ThomasR

Avatar von ThomasR

Update

Zitat:

ThomasR schrieb
(...) beim bereits vorgestellten Programm (008 in https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=20758?threadid=20758) aus, in dem man mit (niederländischen...) LOGO-Befehlen einfache Grafiken zeichnen kann(...)

In 046 von "KC85-Farb-Bascoder ergänzen?" gibt es neue Informationen zu den hier in 013 und 016 vorgestellten Programmen.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 06.03.2024 um 16:14 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

023
05.11.2024, 15:34 Uhr
ThomasR

Avatar von ThomasR

Ein einfaches Schachprogramm

"Schaken" https://robhagemans.github.io/basicode/basicode/Best_of_Basicode_6/SCHAKEN.BAS

Vor ein paar Monaten fand ich dieses Schachprogramm. Es basiert auf einem Buch, das man hier:
https://archive.org/details/mit-basic-ran-ans-schachprogramm-fur-commodore-64 herunterladen kann. Dort wird auch erklärt, dass es nicht geschrieben wurde, um Deep Blue Paroli zu bieten, sondern um ein Projekt zu haben, mit dem ein Anfänger sich in die BASIC-Programmierung hineinarbeiten kann. Das im Prinzip gleiche Buch kam auch noch für den Amstrad CPC heraus. Siehe auch hier: https://joyce.de/basicode/joyce/schach.htm

In diesem Buch: https://archive.org/details/basic-schritt-fur-schritt-mit-sharp-mz-700
ist eine frühere Version des Programms zu finden. Hier sind allerdings nicht die einzelnen Abschnitte so ausführlich wie im erstgenannten Buch beschrieben.

Natürlich weiß ich, dass es auf dem KC z.B. Chessmaster gibt. Mich fasziniert jedoch die Tatsache, dass auch unter BasiCode, wenn auch mit Einschränkungen, Schach möglich ist.

Das Programm (links oben im Bild das ungefähre Aussehen auf dem Commodore 64) hat also keine ausgeklügelte Strategie und kann nicht zwölf Züge im Voraus alle Möglichkeiten gegeneinander abwägen, aber es beherrscht die Spielregeln einschließlich der Rochade und der Umwandlung eines Bauern beim Erreichen der letzten Reihe, doch nicht des en-passant-Schlagens (im Bild rechts unten: Unmittelbar nach B7-B5 von Schwarz wäre A5-B6 ein zulässiger Zug gewesen, wurde aber vom Programm nicht angenommen.). Natürlich ist es auch nicht so schnell wie ein Maschinencode-Programm. Ein niederländischer Hobbyist passte es an BasiCode (noch in Version 2) an. Dort arbeitete er auch die Funktion ein, die im erstgenannten Buch noch als Vorschlag enthalten war, nämlich Start- und Zielfeld eines Zuges blinken zu lassen - so muss man nicht minutenlang auf den Bildschirm starren, um die Veränderung mitzubekommen. Ein weiterer Vorschlag aus dem Buch ist, bestimmte Stellungen eingeben zu können, doch das scheitert wohl bei vielen Computern am ausreichend großen RAM.

Die weißen Figuren werden durch Großbuchstaben dargestellt, entsprechend die schwarzen (die immer der Computer führt) mit Kleinbuchstaben.

Die Ausgabe des BasiCode-Programms ist sehr schlicht, deswegen habe ich (neben der Übertragung ins Deutsche) ein paar Zeilen abgeändert oder ergänzt, um auf dem KC 85 eine angenehmere Optik zu erreichen. Dieses, somit nicht mehr uneingeschränkt auf andere Computer übertragbare, Programm könnt Ihr hier http://www.kc85emu.de/rt/schaken.uuu herunterladen - ein weiteres Mal Danke an FL! Es ist eine Textdatei (.UUU) und enthält bereits die erforderlichen Bascoder-Routinen (lässt also die verzichtbaren weg - wegen der bereits erwähnten Knappheit an RAM). Für CAOS-Versionen ab 4 kann die Zeile 20700 aktiviert werden, sie ist zuständig für den inversen Druck von Schriftzeichen, was die Optik noch einmal verbessert (links unten im Bild).
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 05.11.2024 um 15:44 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

Seiten: -1- [ Technische Diskussionen ]