Robotrontechnik-Forum

Registrieren || Einloggen || Hilfe/FAQ || Suche || Mitglieder || Home || Statistik || Kalender || Admins Willkommen Gast! RSS

Robotrontechnik-Forum » Technische Diskussionen » Arduino IDE nerviger Fehler beim kompilieren » Themenansicht

Autor Thread - Seiten: -1-
000
10.07.2020, 15:34 Uhr
wpwsaw

Avatar von wpwsaw

ich will gerade ein ESP2866 mit Firmware laden und erhalte dauernd eine Fehlermeldung

####################################################
Arduino: 1.8.13 (Windows 7), Board: "Generic ESP8266 Module, 80 MHz, Flash, ck, 26 MHz, 40MHz, QIO, 512K (no SPIFFS), 2, v2 Lower Memory, Disabled, None, Only Sketch, 115200"

CUsers\WPW-HOME\Documents\Arduino\libraries\Time-master\DateStrings.cpp: In function 'char* monthStr(uint8_t)':

CUsers\WPW-HOME\Documents\Arduino\libraries\Time-master\DateStrings.cpp:76:66: error: 'strcpy_P' was not declared in this scope

strcpy_P(buffer, (PGM_P)pgm_read_word(&(monthNames_P[month])));

^

CUsers\WPW-HOME\Documents\Arduino\libraries\Time-master\DateStrings.cpp: In function 'char* dayStr(uint8_t)':

CUsers\WPW-HOME\Documents\Arduino\libraries\Time-master\DateStrings.cpp:90:61: error: 'strcpy_P' was not declared in this scope

strcpy_P(buffer, (PGM_P)pgm_read_word(&(dayNames_P[day])));

^
exit status 1

Fehler beim Kompilieren für das Board Generic ESP8266 Module.

#####################################################

bei meinem Notebook funktioniert es ohne Probleme. Eigentlich habe ich alle Bibliotheken drin.

hat jemand eine IDEE?

wpw
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
001
10.07.2020, 20:17 Uhr
wpwsaw

Avatar von wpwsaw

ich habe mal im Arduino-Forum gelesen, da schreiben sie sinngemäß der Fehler liegt am Programm und nicht an IDE, aber wenn der selbe Sketch auf einem anderen Computer fehlerfrei compiliert wird und auf einem anderen nicht, kann es ja nicht am sketch liegen.

ich habe schon die neuste IDE Version installiert, die notwendigen Bibliotheken gelöscht und neu installiert.....

im Moment gehen mir die Ideen aus....
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
002
10.07.2020, 21:23 Uhr
Heiko_P



Hast du eventuell verschiedene Versionen von Bibliotheken auf beiden Rechnern? Da ich deinen Quelltext nicht kenne kann ich nur raten ...

Gruß
Heiko
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
003
10.07.2020, 21:40 Uhr
wpwsaw

Avatar von wpwsaw

hier mal der Sketch, bisschen lang


Quellcode:


#include <Time.h>
#include <TimeLib.h>

/*

Emulator DCF77
Simulate a DCF77 radio receiver with a ESP8266, esp01 model
Emits a complete three minute pulses train from the GPIO2 output
the train is preceded by a single pulse at the lacking 59° pulse to allow some clock model synchronization
of the beginning frame
after the three pulses train one more single pulse is sent to safely close the frame
get the time from the ntp service

Uses Time library to facilitate time computation


Known issue:
-When the DayLightSaving mode change, the three minutes packet is not checked for possible changes of hour across the frame
  itself, moreover the daylight saving is changed normally at 3 o clock in the morning (here in italy), while I don't correct for it
  so the time will be probably incorrect before at least 03:03 then dayLightSaving changes
-the exact "second" precision is not guaranteed because of the semplicity of the NTP imnplementation
  normally the packet transit delay would be taken into account, but here is not

Fuso68 05/12/2015

19/12/2015 added disconnect and reconnect if wlan fail, reconnect also after three failed ntp requests
20/12/2015 increased wlan connect timeout to 30 seconds


  
Based upon:
Udp NTP Client

Get the time from a Network Time Protocol (NTP) time server
Demonstrates use of UDP sendPacket and ReceivePacket
For more on NTP time servers and the messages needed to communicate with them,
see http://en.wikipedia.org/wiki/Network_Time_Protocol

created 4 Sep 2010
by Michael Margolis
modified 9 Apr 2012
by Tom Igoe
updated for the ESP8266 12 Apr 2015
by Ivan Grokhotkov

This code is in the public domain.

*/

#include <ESP8266WiFi.h>
#include <WiFiUdp.h>
#include <Ticker.h>
//#include <Time.h>


char ssid[] = "your_network_name";  //  your network SSID (name)
char pass[] = "network_password";       // your network password


unsigned int localPort = 2390;      // local port to listen for UDP packets

/* Don't hardwire the IP address or we won't get the benefits of the pool.
*  Lookup the IP address for the host name instead */
IPAddress timeServerIP; // time.nist.gov NTP server address
const char* ntpServerName = "0.nl.pool.ntp.org";

const int NTP_PACKET_SIZE = 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
WiFiUDP udp;

//udp reply missing counter
int UdpNoReplyCounter = 0;

//routine timer 100 msec
Ticker DcfOutTimer;

#define LedPin 2

//how many total pulses we have
//three complete minutes + 2 head pulses and one tail pulse
#define MaxPulseNumber 183
#define FirstMinutePulseBegin 2
#define SecondMinutePulseBegin 62
#define ThirdMinutePulseBegin 122


//complete array of pulses for three minutes
//0 = no pulse, 1=100msec, 2=200msec
int PulseArray[MaxPulseNumber];

int PulseCount = 0;
int DCFOutputOn = 0;
int PartialPulseCount = 0;
int ThisHour,ThisMinute,ThisSecond,ThisDay,ThisMonth,ThisYear,DayOfW;

const int timeZone = 1;     // Central European Time

int Dls;                    //DayLightSaving

void setup()
{
  Serial.begin(9600);
  Serial.println();
  Serial.println("INIT DCF77 emulator");

  pinMode(LedPin, OUTPUT);
  digitalWrite(LedPin, LOW);
  
  //handle DCF pulses
  DcfOutTimer.attach_ms(100, DcfOut);

  //first 2 pulses: 1 + blank to simulate the packet beginning
  //il primo bit e' un 1
  PulseArray[0] = 1;
  //missing pulse indicates start of minute
  PulseArray[1] = 0;

  //last pulse after the third 59° blank
  PulseArray[MaxPulseNumber - 1] = 1;
  
  PulseCount = 0;
  DCFOutputOn = 0;    //we begin with the output OFF

  //first connect to wifi network
  //NOTE testing WiFi.status() BEFThisHour the FIRST WiFi.begin() seems to hang the system
  //so we attempt a first connection BEFORE the main loop
  ConnectToWiFi();
}

void loop(){
  
  //check the WLAN status
  if (WiFi.status() == WL_CONNECTED)
     ReadAndDecodeTime();
  else
    ConnectToWiFi();

  delay(60000);

}


void ConnectToWiFi(){
  int Timeout;

  WiFi.disconnect();
  Serial.println("Disconnected !");
  delay(1000);        //necessary ???
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, pass);
  Timeout = 0;
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    if (Timeout++ > 60){
      Serial.println("\nImpossible to connect to WLAN!");
      WiFi.disconnect();
      return;
    }
  };
  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

}

void ReadAndDecodeTime() {

  int DayToEndOfMonth,DayOfWeekToEnd,DayOfWeekToSunday;

  //get a random server from the pool
  WiFi.hostByName(ntpServerName, timeServerIP);

  Serial.println("Starting UDP");
  udp.begin(localPort);
  Serial.print("Local port: ");
  Serial.println(udp.localPort());

  sendNTPpacket(timeServerIP); // send an NTP packet to a time server
  // wait to see if a reply is available
  delay(1000);
  
  int cb = udp.parsePacket();
  if (!cb) {
    Serial.println("no packet yet");
    //try max 3 times (every minute) after that we force the wifi to reconnect
    if (UdpNoReplyCounter++ == 3){
      Serial.println("Too many UDP errors");
      ConnectToWiFi();
      UdpNoReplyCounter = 0;
    };
  } else {
    UdpNoReplyCounter = 0;
    Serial.print("packet received, length=");
    Serial.println(cb);
    // We've received a packet, read the data from it
    udp.read(packetBuffer, NTP_PACKET_SIZE); // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);

    // now convert NTP time into everyday time:
    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // subtract seventy years:
    //note: we add two minutes because the dcf protocol send the time of the FOLLOWING minute
    //and our transmission begins the next minute more
    time_t ThisTime = secsSince1900 - seventyYears + ( timeZone * 3600 ) + 120;
    // print Unix time:
    Serial.println(ThisTime);

    //calculate actual day to evaluate the summer/winter time of day ligh saving
    DayOfW = weekday(ThisTime);
    ThisDay = day(ThisTime);
    ThisMonth = month(ThisTime);
    ThisYear = year(ThisTime);
    Serial.print("Local time");       // UTC is the time at Greenwich Meridian (GMT)
    Serial.print(ThisDay);
    Serial.print('/');
    Serial.print(ThisMonth);
    Serial.print('/');
    Serial.print(ThisYear);
    Serial.print(' ');
  
    //check daylight saving
    Dls = 0;    //default winter time
    //From April to september we are surely on summer time
    if (ThisMonth > 3 && ThisMonth < 10) {
      Dls = 1;
    };
    //March, month of change winter->summer time, last Sunday of the month
    //March has 31 days so from 25 included on Sunday we can be in summer time
    if (ThisMonth == 3 && ThisDay > 24) {
      DayToEndOfMonth = 31 - ThisDay;
      DayOfWeekToSunday = 7 - DayOfW;
      if (DayOfWeekToSunday >= DayToEndOfMonth)
        Dls = 1;
    };
    //October, month of change summer->winter time, last Sunday of the month
    //October has 31 days so from 25 included on Sunday we can be in winter time
    if (ThisMonth == 10) {
      Dls = 1;
      if (ThisDay > 24) {
        DayToEndOfMonth = 31 - ThisDay;
        DayOfWeekToEnd = 7 - DayOfW;
        if (DayOfWeekToEnd >= DayToEndOfMonth)
        Dls = 0;
      };
    };

    Serial.print("Dls:");
    Serial.print(Dls);
    Serial.print(' ');
    //add one hour if we are in summer time
    if (Dls == 1)
      ThisTime += 3600;

    //now that we know the dls state, we can calculate the time to
    // print the hour, minutes and seconds:
    ThisHour = hour(ThisTime);
    ThisMinute = minute(ThisTime);
    ThisSecond = second(ThisTime);
    Serial.print(ThisHour); // print the hour
    Serial.print(':');
    Serial.print(ThisMinute); // print the minute
    Serial.print(':');
    Serial.println(ThisSecond); // print the second

    //if we are over about the 56° second we risk to begin the pulses too late, so it's better
    //to skip at the half of the next minute and NTP+recalculate all again
    if (ThisSecond > 56){
      delay(30000);
      return;      
    }

    //calculate bis array for the first minute
    CalculateArray(FirstMinutePulseBegin);

    //add one minute and calculate array again for the second minute
    ThisTime += 60;
    DayOfW = weekday(ThisTime);
    ThisDay = day(ThisTime);
    ThisMonth = month(ThisTime);
    ThisYear = year(ThisTime);
    ThisHour = hour(ThisTime);
    ThisMinute = minute(ThisTime);
    ThisSecond = second(ThisTime);
    CalculateArray(SecondMinutePulseBegin);

    //one minute more for the third minute
    ThisTime += 60;
    DayOfW = weekday(ThisTime);
    ThisDay = day(ThisTime);
    ThisMonth = month(ThisTime);
    ThisYear = year(ThisTime);
    ThisHour = hour(ThisTime);
    ThisMinute = minute(ThisTime);
    ThisSecond = second(ThisTime);
    CalculateArray(ThirdMinutePulseBegin);

  
    //how many to the minute end ?
    //don't forget that we begin transmission at second 58°
    int SkipSeconds = 58 - ThisSecond;
    delay(SkipSeconds * 1000);
    //begin
    DCFOutputOn = 1;

    //three minutes are needed to transmit all the packet
    //then wait more 30 secs to locate safely at the half of minute
    //NB 150+60=210sec, 60secs are lost from main routine
    delay(150000);

  };

  udp.stop() ;

}





void CalculateArray(int ArrayOffset) {
  int n,Tmp,TmpIn;
  int ParityCount = 0;

  //first 20 bits are logical 0s
  for (n=0;n<20;n++)
    PulseArray[n+ArrayOffset] = 1;

  //DayLightSaving bit
  if (Dls == 1)
    PulseArray[17+ArrayOffset] == 2;
  else
    PulseArray[18+ArrayOffset] == 2;
    
  //bit 20 must be 1 to indicate time active
  PulseArray[20+ArrayOffset] = 2;

  //calculate minutes bits
  TmpIn = Bin2Bcd(ThisMinute);
  for (n=21;n<28;n++) {
    Tmp = TmpIn & 1;
    PulseArray[n+ArrayOffset] = Tmp + 1;
    ParityCount += Tmp;
    TmpIn >>= 1;
  };
  if ((ParityCount & 1) == 0)
    PulseArray[28+ArrayOffset] = 1;
  else
    PulseArray[28+ArrayOffset] = 2;

  //calculate hour bits
  ParityCount = 0;
  TmpIn = Bin2Bcd(ThisHour);
  for (n=29;n<35;n++) {
    Tmp = TmpIn & 1;
    PulseArray[n+ArrayOffset] = Tmp + 1;
    ParityCount += Tmp;
    TmpIn >>= 1;
  }
  if ((ParityCount & 1) == 0)
    PulseArray[35+ArrayOffset] = 1;
  else
    PulseArray[35+ArrayOffset] = 2;
   ParityCount = 0;
  //calculate day bits
  TmpIn = Bin2Bcd(ThisDay);
  for (n=36;n<42;n++) {
    Tmp = TmpIn & 1;
    PulseArray[n+ArrayOffset] = Tmp + 1;
    ParityCount += Tmp;
    TmpIn >>= 1;
  }
  //calculate weekday bits
  TmpIn = Bin2Bcd(DayOfW);
  for (n=42;n<45;n++) {
    Tmp = TmpIn & 1;
    PulseArray[n+ArrayOffset] = Tmp + 1;
    ParityCount += Tmp;
    TmpIn >>= 1;
  }
  //calculate month bits
  TmpIn = Bin2Bcd(ThisMonth);
  for (n=45;n<50;n++) {
    Tmp = TmpIn & 1;
    PulseArray[n+ArrayOffset] = Tmp + 1;
    ParityCount += Tmp;
    TmpIn >>= 1;
  }
  //calculate year bits
  TmpIn = Bin2Bcd(ThisYear - 2000);   //a noi interesa solo l'anno con ... il millenniumbug !
  for (n=50;n<58;n++) {
    Tmp = TmpIn & 1;
    PulseArray[n+ArrayOffset] = Tmp + 1;
    ParityCount += Tmp;
    TmpIn >>= 1;
  }
  //date parity
  if ((ParityCount & 1) == 0)
    PulseArray[58+ArrayOffset] = 1;
  else
    PulseArray[58+ArrayOffset] = 2;

  //last missing pulse
  PulseArray[59+ArrayOffset] = 0;

  /* for debug: print the whole 180 secs array
   * Serial.print(':');
  for (n=0;n<60;n++)
    Serial.print(PulseArray[n+ArrayOffset]);*/

}


// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(IPAddress& address)
{
  Serial.println("sending NTP packet...");
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:
  udp.beginPacket(address, 123); //NTP requests are to port 123
  udp.write(packetBuffer, NTP_PACKET_SIZE);
  udp.endPacket();
}


//called every 100msec
//for DCF77 output
void DcfOut() {

  if (DCFOutputOn == 1) {
    switch (PartialPulseCount++) {
      case 0:
        if (PulseArray[PulseCount] != 0)
          digitalWrite(LedPin, 0);
        break;
      case 1:
        if (PulseArray[PulseCount] == 1)
          digitalWrite(LedPin, 1);
        break;
      case 2:
        digitalWrite(LedPin, 1);
        break;
      case 9:
        if (PulseCount++ == (MaxPulseNumber -1 )){     //one less because we FIRST tx the pulse THEN count it
          PulseCount = 0;
          DCFOutputOn = 0;
        };
        PartialPulseCount = 0;
        break;
    };
  };

}

int Bin2Bcd(int dato) {
  int msb,lsb;

  if (dato < 10)
    return dato;
  msb = (dato / 10) << 4;
  lsb = dato % 10;
  return msb + lsb;
}



--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
004
10.07.2020, 21:44 Uhr
wpwsaw

Avatar von wpwsaw

auf die schnelle

esp8266 verbindet sich per WLAN mit fritzbox, holt sich über UDP die aktuelle Zeit, wandelt sie in ein DCF Signal um und gibt je nach programmierung ein positives bzw. negertives signal über ein PortPin aus und kann als ersatz für ein DCF Modul eingesetzt werden.

wpw
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
005
11.07.2020, 11:25 Uhr
Enrico
Default Group and Edit


Ist aber schon ganz schön kompliziert, was Du da so machst.
Ist bei Dir der DCF-Empfang so schlecht?
--
MFG
Enrico
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
006
11.07.2020, 13:13 Uhr
Heiko_P



@Enrico: Sowas ähnliches habe ich auch gemacht, bei mir ist der DCF-Empfang nicht besonders gut. Mit sochen Schaltungen lässt sich z.B. der Digitalteil einer DCF-Uhr testen bevor man an den Aufbau der Empfängerschaltung geht (und im Zweifelsfall nicht weiß wo man einen Fehler suchen muss).

@wpwsaw: Ich habe den Code problemlos komplieren können, es muss also auf deinem PC wo es nicht geht irgendein Problem geben.

Die als Fehler gemeldete Funktion 'strcpy_P' kommt in deinem Sketch nicht vor, also fehlt irgendwo eine Library oder du hast an der Stelle eine falsche Version erwischt. Mit beiden Problemen hatte ich bereits zu tun ...

Gruß
Heiko
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
007
11.07.2020, 19:46 Uhr
wpwsaw

Avatar von wpwsaw

@Enrico
ist nicht auf meinem Mist gewachsen, ich habe es nur an meine Bedürfnisse angepasst. Es gibt fertige LP wo du nur den esp drauf steckst und es werden die gleichen Anschlüsse genutzt wie bei einem DCF Modul, also DCF raus ESP Modul rein und fertig. Natürlich muss im Sketch die entsprechenden Daten für deine Fritzbox noch rein. Und ja, bei mir ist so gut wie kein Empfang, zumindestens für handelsüblichen Module. Komisch ist, das ich ein paar alte Funkuhren habe (Wand und Wecker) die haben Empfang, zumindestens laufen die immer genau und stellen auch Sommer und Winter die Zeit um.

@Heiko

ja, ich weiß, das Problem habe ich seit ich meinen neuen 3000 Euro Rechner fertig gemacht habe. Der brauch 5x solange zum hochfahren wie ein 15 Jahre alter Siemens Industrierechner, den ich mit WIN Server 2019 laufen habe. Also weiter probieren.

Ich hatte auch mit den Bibliotheken zum betreiben von den RTC Modulen Probleme, diese konnte ich aber durch nachinstallieren und Tausch von Bibliotheken zum compilieren überzeugen.

Dann hoffe ich mal, das mein Notebook, wo es funzt, noch ne Weile durchhält

Danke

wpw
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
008
11.07.2020, 20:13 Uhr
Enrico
Default Group and Edit


Hängt davon ab, was in der Nähe ist.
Kann sein, dass Deine Nixieuhr zu stark strahlt.

Mir stört der Monitor.
Ist die Antenne 2m entfernt klappt das hier ganz gut.
Hängt aber stark vom Wetter, uvm. ab.
--
MFG
Enrico
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
009
11.07.2020, 20:19 Uhr
wpwsaw

Avatar von wpwsaw

bei liegt es an den vielen Funkgeräten

sogar meine Garagentorsteuerung will nicht mehr so. Früher konnte ich 500m vorher das Tor öffnen, heute nur wenn ich von der richtigen Seite 15m vor dem Tor stehe.
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
010
11.07.2020, 20:31 Uhr
Heiko_P



@wpwsaw:
Versuche mal die Erweiterung für die ESP8266-Boards neu zu installieren, vielleicht funktioniert es dann.

Ich empfehle dir auch, auf allen Rechnern die gleiche Version der IDE zu verwenden, auch wenn es evtl schon neuere Versionen gibt.

Viele Grüße
Heiko

Dieser Beitrag wurde am 11.07.2020 um 20:33 Uhr von Heiko_P editiert.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
011
11.07.2020, 20:41 Uhr
felge1966

Avatar von felge1966

Ich hatte das ganze mal mit einem Demos D1 getestet und auch ohne Auffälligkeiten.


Gruß Jörg
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
012
11.07.2020, 20:58 Uhr
wpwsaw

Avatar von wpwsaw

ja, es funktioniert ja auf meinem Notebook, nur nicht auf dem neuen Rechner
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
013
29.07.2020, 16:36 Uhr
Guido
Default Group and Edit
Avatar von Guido

Ich habe ja für das GPS-Normal auch den Einstieg ins Arduinogedöhns gewagt und hatte prompt auch Probleme.
Zunächst war mein allererster Arduino "out of Tüte" defekt (und blöderweise schon eingelötet) doch bis ich dahinter kam habe ich ein paar Kopfstände gemacht.

Dann hatte ich immer wieder mal Fehlermeldungen, die sich nicht orten ließen. Letztlich war zum einen die IDE (1.8.12) wohl schuld und die Verzeichnistiefe zum Projekt auf meinem "Server" (eher ein aufgebohrtes NAS) einfach zu lang.

Die als Fehler gemeldeten Sketche bzw. die Nanos damit, funktionierten dennoch wie sie sollen.

Guido
--
Der Mensch hat drei Wege, klug zu handeln.
Erstens durch Nachdenken: Das ist der edelste.
Zweitens durch Nachahmen: Das ist der leichteste.
Drittens durch Erfahrung: Das ist der bitterste.

Konfuzius

Dieser Beitrag wurde am 29.07.2020 um 16:37 Uhr von Guido editiert.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
014
29.07.2020, 17:18 Uhr
wpwsaw

Avatar von wpwsaw

... ja, es sind auch manchmal die unterschiedlichen Versionen der Bibliotheken.

es nervt bei mir nur, weil ich mehrere Rechner habe, mit denen ich arbeite. Die Daten liegen auch auf einem NAS Server. Und wenn ich dann von einem zum anderen Rechner wechsel und dort weiter arbeite und das gemecker geht wieder los, das schafft einen.

wpw
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
015
29.07.2020, 21:16 Uhr
Heiko_P



Es gibt für Windows eine mobile Version der IDE, die lässt sich einfach auf das NAS (oder auch in eine Cloud) laden und von dort ausführen, dann hast du auf allen Rechnern immer den gleichen Datenbestand. Diese Variante nutze ich zur Zeit für meine Windows-Rechner. Für Linux scheint es so eine Version jedoch nicht zu geben, hier müßte man die entsprechenden Ordner auf anderem Weg synchronisieren.

Gruß
Heiko
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
016
30.07.2020, 08:22 Uhr
wpwsaw

Avatar von wpwsaw

diese Version hatte ich auch in mit in Benutzung. Vom Server aus starten ist auch eine Variante, Danke

wpw
--
RECORD, CRN1; CRN2; PicoDat; LC80; Poly880; KC85/2,3,4,5 ; KC87; Z1013; BIC; PC1715; K8915; K8924; A7100; A7150; EC1834; ab jetzt ohne Tatra813-8x8 aber mit W50LA/Z/A; P3; ES175/2
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
Seiten: -1-     [ Technische Diskussionen ]  



Robotrontechnik-Forum

powered by ThWboard 3 Beta 2.84-php5
© by Paul Baecher & Felix Gonschorek