081
07.06.2017, 08:21 Uhr
P.S.
|
@maleuma <062>
Ob der "Klemm"-Code die 80Z/Z-Routine enthält und überhaupt für den KC85/3 geeignet ist, habe ich dem Test nicht entnehmen können.
Nachdem mir nun endlich das Einlesen meiner auf Kassette vorhandenen KC85-Datein gelungen ist - hier vorab mal der Quellcode der 80-Zeichen/Zeile-Routine, wie im CAOS 2.4 und WORDPRO'86:
| Quellcode: |
SHOW LD HL,0B980H ;80-ZEICHEN-ROUT
LD B,0 ;ZEICHEN IN A
SLA A
RL B
SLA A
RL B
LD C,A
ADD HL,BC
LD (ARG),HL
LD B,8
LAB10 LD HL,(COL)
SRL L
PUSH AF
LD A,L
CP 20H
JR NC,CALC1
LD A,3
AND H
RLCA
RLCA
LD D,A
LD A,0CH
AND H
RRCA
RRCA
LD E,A
LD A,H
AND 0F0H
OR E
OR D
LD H,A
LD DE,8000H
XOR A
CALC2 RR H
RRA
RR H
RRA
RR H
RRA
OR L
LD L,A
ADD HL,DE
JR CALC3
CALC1 SUB 20H
LD L,A
LD A,33H
AND H
RLCA
RLCA
RLCA
RLCA
LD E,A
LD A,H
AND 0CCH
OR E
LD H,A
XOR A
LD DE,0A000H
RR H
RRA
RR H
RRA
JR CALC2
LAB1 JR LAB10
CALC3 EX DE,HL
LD HL,(ARG)
LD C,(HL)
BIT 0,B
JR NZ, HO
LD A,C
RRA
RRA
RRA
RRA
LD C,A
JR LAD
HO INC HL
LAD LD (ARG),HL
EX DE,HL
LD A,(FLAG)
BIT 0,A
JR Z,LAB2
LD A,C
CPL
LD C,A
LAB2 POP AF
JR C,LAB3
RLD
LD A,C
RRD
JR LAB4
LAB3 RRD
LD A,C
RLD
LAB4 LD A,(LINE)
INC A
LD (LINE),A
DJNZ LAB1
SUB 8
LD (LINE),A
RET
|
... ist ein Auszug aus dem "EdAss1.0" (ausführlich beim nächsten Update meiner HP), einem von mir damals angefangenen Editor/Assembler auf eben dieser Grundlage, als Weiterentwicklung und Verbesserung des Development-Moduls M27 im Zusammenhang mit einem verbesserten Test-Monitor ... ist leider nie mehr weiter bearbeitet worden.
Das Wissen der Menschheit gehört allen Menschen! -
Wissen ist Macht - wer nur glaubt, der weis nichts! -
Jedoch - Unwissenheit schützt vor Strafe nicht! -
Gegen die Ausgrenzung von Unwissenden und für ein liberalisiertes Urheberrecht!
PS
Dieser Beitrag wurde am 07.06.2017 um 08:22 Uhr von P.S. editiert. |
