Robotrontechnik-Forum

Registrieren || Einloggen || Hilfe/FAQ || Suche || Mitglieder || Home || Statistik || Kalender || Admins

Willkommen Gast!

Robotrontechnik-Forum » Technische Diskussionen » Neue Spiele für den robotron BIC A5105 » Themenansicht

Autor

Thread - Seiten: -1-

000
30.03.2023, 19:08 Uhr
BICa5105

Hallo,

da ich immer mal wieder neue (Basic) Spiele für den BIC programmieren, erweitern oder von MSX anpassen möchte, mache ich hier ein entsprechendes Thema auf.

Hier der Link des Ordners bei Dropbox:
(Die Dateien können ohne Anmeldung bei Dropbox heruntergeladen werden.)

https://www.dropbox.com/sh/z7ceexjl72ehb9k/AAAGYkwDzgpr1wei5n4CVLfga?dl=0

Die Programme starten automatisch. Ansonsten immer mit der AUTOEXEC.BAS starten!
Die Spiele sind auch im JKCEMU spielbar. Dort kann es allerdings, wegen eines Fehlers im Emulator, zu Grafik- und/oder Soundfehlern kommen.
Es ist immer eine gepackte Version der Einzeldateien und eine DSK dabei.

Neu im Ordner ist das Spiel "Laternen". Ein nicht ganz einfaches Knobelspiel.

LG Cornelius
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

001
06.04.2023, 15:14 Uhr
ThomasR

Avatar von ThomasR

Rubik's Cube auf dem BIC

Heute möchte ich ein Programm vorstellen, das zwar nicht von mir stammt (mehr Details hier: https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=13599&time=1680682758&s=38957e04c43d7e9b98818c4b764ff63f
), aber in das ich einige Arbeit gesteckt habe, um es auf dem BIC nutzbar zu machen. Frank hat es freundlicherweise auf seine Website hochgeladen: http://www.kc85emu.de/rt/kubusbic.asc .

Hier ist es ready-to-use, doch eigentlich setzt es sich aus drei Bestandteilen zusammen: dem Bascoder, der Farberweiterung zum Bascoder und dem Programm von 1985 eines belgischen Autors.

Meine ersten Schritte auf dem (leider nur emulierten) BIC habe ich in den KC-News 1 / 2006 geschildert. https://www.iee.et.tu-dresden.de/~kc-club/02/0201.HTML#1/06 . Damals erweiterte ich den Bascoder des BIC auf Farbtauglichkeit.

Das Zauberwürfel-Programm ist verständlicherweise sehr umfangreich. Für den RAM des BIC wurde es zu groß. Ursprünglich war es ein BasiCode-2-Programm, daher konnte ich die Routinen oberhalb der 350 löschen, das Programm nutzt nur den Textbetrieb. Der Platz war weiterhin nicht ausreichend, deswegen flog auch noch die Beschreibung raus (man kann sie in der ursprünglichen bzw. in der eingedeutschten Fassung nachlesen, aber die Bedienung ist sowieso intuitiv genug).

Im letzten Bild sieht man zwei alternative Varianten für die Klebe-Etiketten des Würfels, welche einem am besten gefallen, kann man in den Zeilen 4240 und 6970 ersetzen.

Das Programm (das durchgängig mit Großbuchstaben bedient wird) bietet drei Möglichkeiten:

- Von einem "aufgeräumten" Würfel ausgehend kann man (Grund-Achsen immer beibehalten, nicht den kompletten Würfel drehen!) die vordere, hintere, linke, rechte obere bzw. untere Ebene drehen und schließlich vom Programm wieder in Ordnung bringen lassen.

In manchen Fällen resigniert das Programm beim Lösen einer selbst eingegebenen Stellung, aber viele Lösungen schafft es tatsächlich. Natürlich darf man keine Kombinationen eingeben, die am realen Zauberwürfel nur durch Herausnehmen und verkehrt-wieder-Einsetzen eines Eck- oder Kantenteils (oder Wechseln von Klebeetiketten) erzeugt werden können. Hier entsteht eine Fehlermeldung, denn der Autor hat verschiedene Kniffe angewendet, um den komplexen Algorithmus im verfügbaren RAM unterzubringen. Einer davon ist, für nicht auftretende Fälle eine nicht existiereende Zeilennummer zu verwenden:

Quellcode:

...
4530 IF A>6 THEN 4560
4540 ON A GOSUB 1,1,10450,1,10860,10870
4550 GOTO 4570
...

Das hat mich lange irritiert, ich hielt das für Übertragungsfehler und dachte, das Programm sei nicht lauffähig.

- Man kann seinen (verdrehten) realen Würfel Teilfläche für Teilfläche ins Programm eingeben und dann das Programm lösen lassen.

- Zu guter Letzt gibt es noch eine Demonstration von über einem Dutzend regelmäßigen Mustern nebst jeweils einer Anleitung, wie dieses Muster aus der Grundstellung zu erreichen ist.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 06.04.2023 um 15:52 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

002
06.04.2023, 16:22 Uhr
ralle

Problem ist hier der zur Verfügung stehende BASIC-Speicher. Beim KC85 bis zu 48kb, aber bei BIC nur 25kb.
--
Gruß Ralle

Wenn Sie dazu neigen, Bedienungsanleitungen zusammen mit dem Verpackungsmaterial wegzuwerfen, sehen Sie bitte von einem derart drastischen Schritt ab!...
... Nachdem Sie das Gerät eine Weile ausprobiert haben, machen Sie es sich am besten mit dieser Anleitung und ihrem Lieblingsgetränk ein oder zwei Stunden lang in Ihrem Sessel bequem. Dieser Zeitaufwand wird Sie dann später belohnen...

aus KENWOOD-Bedienungsanleitung TM-D700

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

003
10.04.2023, 11:11 Uhr
BICa5105

Hallo,

zu: Rubik's Cube auf dem BIC

Der BIC hat die "nur" 25kB Basic Speicher für Anwenderprogramme, weil das so vom MSX übernommen wurde. Die ganze Speicherverwaltung ist da komplett anders als zb beim KC.
Das reicht im Normalfall auch völlig aus. Der RAM vom BIC ist 64kB groß und der Video RAM 128kB (8Bit bzw.64kB 16Bit).

Ich habe mal den Code vom Spiel überflogen...soweit ich das sehen kann wird der Grafikspeicher gar nicht genutzt und alles im Screen0 (Textscreen) gemacht.
Wenn man den ganzen "grafischen Teil" in den Video Speicher des BIC verlegen würde, dann würde das Programm nicht mehr so viel Programmspeicher fressen.
Ich glaube, es sind auch Speicher Reservierungen drin die man so nicht bräuchte und es werden sehr viele Variablen benutzt.

LG Cornelius
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

004
15.04.2023, 20:24 Uhr
maleuma

Ich wollte das BASICODE-Programm gern einmal auf dem KC85 ausprobieren.
Wo finde ich die aktuelle, farbige Version von Rubik's Cube?
In der Dropbox finde ich nur Alien, Break und Laternen ...
--
Mario.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

005
16.04.2023, 15:15 Uhr
ThomasR

Avatar von ThomasR

Es ist im riesigen Textkasten im Post Nr. 000 von https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=20758&s=94e1cef79a926b8aba852614f3669ad5 .

Aber zwischenzeitlich hat es Frank freundlicherweise auch hier http://www.kc85emu.de/rt/kubuskcc.bas untergebracht.

Viel Spaß damit!
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 16.04.2023 um 15:22 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

006
21.04.2023, 16:50 Uhr
BICa5105

.
.
Hallo,

ich habe mal das mini Spiel "Hanoi" von robotron, welches Ulrich Zander 2015 für den BIC angepasst hat, noch ein wenig "aufgehübscht".

Habe die Steuerung vereinfacht, ein bisschen Grafik ins Spiel gebracht und die Möglichkeit nach Zeit oder Zügen zu spielen.
Man kann jetzt auch 3 Schwierigkeitsstufen wählen. Ein paar Soundeffekte sind auch dazugekommen.
Es gibt jetzt auch eine englische Version (kann man im Menu wählen).

Auch gut im JKCEMU spielbar.
HANOI23.DSK einfach laden, Reset und das Spiel startet.
Ansonsten autoexec.bas starten.

Hier der Link zu HANOI23 (Ordner BICGames):

https://www.dropbox.com/scl/fo/vghl9iaetcql5zu35af3v/h?dl=0&rlkey=1f9nh0bms1q9zy4hwzkbh376f

LG Cornelius
.
.
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

007
17.06.2023, 16:52 Uhr
ThomasR

Avatar von ThomasR

Im Zauberwürfel-Programm (001) ist ein Fehler, auf den mich Frank hinwies:

Quellcode:

...
5930 IF a(7,6)=a(6,7) THEN 5360
5940 IF a(6,6)=a(8,5) THEN a$="=-H-U-R-HR-V-RHRUH-UV":REM <--- erstes Zeichen von a$ falsch!
5950 IF a(6,6)=a(8,5) THEN GOSUB 10540:GOTO 5890
...

muss heißen:

Quellcode:

...
5930 IF a(7,6)=a(6,7) THEN 5360
5940 IF a(6,6)=a(8,5) THEN a$="U-H-U-R-HR-V-RHRUH-UV"
5950 IF a(6,6)=a(8,5) THEN GOSUB 10540:GOTO 5890
...

Das ist mir selbst 2007 unterlaufen, als ich Leerzeichen nach den Schlüsselwörtern einfügte und dergleichen, um das Programm in ASCII-Form auch auf anderen Wegen übertragen zu können. Vele Computerbasics "pochen" auf diese Leerzeichen.

An dieser Stelle wird es nun korrekt fortgesetzt.

Nun sollten alle legalen Eingaben unter Menüpunkt B gelöst werden.

Frank wird den Download http://www.kc85emu.de/rt/kubusbic.asc sicher zeitnah korrigieren, kontrolliert einfach Zeile 5940.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

008
29.06.2023, 12:41 Uhr
BICa5105

Hallo,

habe mal wieder ein mini Spiel von MSX an den BIC angepasst und bisschen erweitert... .
Es handelt sich um den Klassiker "PONG" von Atari.

Hier der Link zum BIC Spiele Ordner bei Dropbox:

https://www.dropbox.com/scl/fo/vghl9iaetcql5zu35af3v/h?dl=0&rlkey=1f9nh0bms1q9zy4hwzkbh376f

Dateien Spiel Pong: BICPONG.DSK und BICPONG.RAR

Spiel mit AUTOEXEC.BAS starten!
Läuft leider nicht im JKCEMU sondern nur am original BIC ! :-(

LG Cornelius
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

009
23.09.2023, 17:37 Uhr
BICa5105

Hallo,

hier mal wieder ein von mir vom MSX an den BIC angepasstes Spiel: Kniffel bzw. Yahtzee.
Ich denke, dass kennt jeder ;-)... da muss man nichts erklären.

Für bis zu 4 Spieler.

Spielbar im JKCEMU und natürlich auf dem original BIC ;-).

BAS und DSK hier herunterladbar:

https://www.dropbox.com/scl/fi/ki724oj9naw6e9rzwzhll/kniffel.bas?rlkey=0h7kcnbl4gug7euwuomfvpmcv&dl=0

https://www.dropbox.com/scl/fi/0ff5nfs3s4uzlc4z3yaaa/Kniffel.dsk?rlkey=s88c8j3h02mg4id55qbpux4s6&dl=0

LG Cornelius
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

010
24.09.2023, 16:19 Uhr
Klaus

Hallo Cornelius,

Danke für Deine Arbeit.
Die kalte Jahreszeit kommt ja bald, dann werde ich Deine Programme mal in Ruhe testen.

Viele Grüße,
Klaus

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

011
05.11.2023, 20:36 Uhr
ThomasR

Avatar von ThomasR

Malcolm Tyrrell schrieb 2003 für den ZX Spectrum MazezaM, ein schön kniffliges Programm, halb Sokoban, halb Labyrinth:

Inzwischen gibt es dieses Knobelspiel auf einigen anderen Computern wie auch für den Windows-PC:

2020 schrieb der Autor eine Version für BasiCode. Es läuft damit, den entsprechenden Bascoder vorausgesetzt, sowohl auf dem BIC als auch auf MSX-Computern:

Die Version ist zwar nicht so farbenfroh wie die beiden vorgenannten Versionen, aber die Herausforderung der Rätsel ist unverändert. Obendrein bietet sie den Vorteil, dass die Zahl der Versuche nicht begrenzt ist und man auch einfach in den nächsten Level springen kann. Aufgabe ist, das Labyrinth zu durchqueren, wofür jeweils eine komplette Zeile von Hindernissen verschoben werden kann.

Die Bedienung erfolgt mit den Cursortasten oder mit den Klein- oder Großbuchstaben i, j, k, l. Wie gewohnt muss zunächst der Bascoder geladen und gestartet werden, dann kann das Programm hinzugeladen werden.

Viel Spaß damit!

Quellcode:

1000 A=194:GOTO 20:REM *** MAZEZAM ***
1010 DIM R$(11):DIM Y(11):HO=14:VE=14
1310 HO=HO+1:R=HO:GOSUB 110:GOSUB 120:IF R=HO THEN 1310
1610 VE=VE+1:S=VE:GOSUB 110:GOSUB 120:IF VE=S THEN 1610
1910 GOSUB 100:VE=6:HO=(R-7)/2:GOSUB 110:PRINT"MazezaM":VE=S-6
1920 HO=0:GOSUB 110:PRINT" MOVE ijkl":PRINT"RETRY r"
1930 PRINT" SKIP s":PRINT" QUIT q":GOSUB 210
1940 IF IN<>81 THEN 1960
1950 GOTO 950
1960 RESTORE:Z=0:N$="":T=0
2210 GOSUB 250:T=T+1:IF T=31 THEN 1910
2220 GOSUB 4910:N=W:GOSUB 4910:M=W:GOSUB 4910:P=W:GOSUB 4910:Q=W
2230 F=0:FOR C=0 TO N-1:R$(C)="":Y(C)=0:FOR D=0 TO M-1:A$="="
2240 IF F=0 THEN GOSUB 4910:F=6
2250 F=F-1:G=INT(W/2)*2:IF W=G THEN A$=" "
2260 R$(C)=R$(C)+A$:W=G/2:NEXT D:NEXT C:U=INT((R-M)/2)
2270 V=INT((S-N)/2)
2510 GOSUB 100
2810 VE=V-1:HO=U-1:W=P:X=0:GOSUB 4610:FOR I=0 TO N-1:Y(I)=0
2820 VE=VE+1:GOSUB 110:A$="#":B$=A$:IF I=P THEN A$=">"
2830 IF I=Q THEN B$=">"
2840 PRINT A$;:GOSUB 4010:PRINT B$:NEXT I:VE=VE+1:GOSUB 4610
2850 HO=HO+1
3110 GOSUB 210:D=W:E=X:IF (IN=73 OR IN=31) AND W>0 THEN D=W-1
3120 IF (IN=75 OR IN=30) AND W<N-1 THEN D=W+1
3130 IF (IN=74 OR IN=28) AND X>0 THEN E=X-1:F=1
3140 IF (IN=76 OR IN=29) AND X<M-1 THEN E=X+1:F=M
3150 IF (IN=76 OR IN=29) AND W=Q AND X=M-1 OR IN=83 THEN 2210
3160 IF IN=81 THEN 1910
3170 IF IN=82 THEN 2810
3180 I=D:GOSUB 4310
3190 IF MID$(J$,E+1,1)=" " THEN I=W:W=D:X=E:GOSUB 3710:GOTO 3410
3200 IF X<>E AND MID$(J$,F,1)=" " THEN Y(W)=Y(W)+E-X:X=E
3410 I=W:GOSUB 3710:GOTO 3110
3710 VE=V+I:GOSUB 110
4010 GOSUB 4310:IF I<>W THEN PRINT J$;:RETURN
4020 IF X>0 THEN PRINT LEFT$(J$,X);
4030 PRINT "@";:IF X<M-1 THEN PRINT RIGHT$(J$,M-X-1);
4040 REM B$="#":IF I=Q THEN B$=">"
4050 REM PRINT B$
4060 RETURN
4310 IF Y(I)=0 THEN J$=R$(I):RETURN
4320 IF Y(I)>0 THEN B=Y(I):C=M-B
4330 IF Y(I)<0 THEN C=-Y(I):B=M-C
4340 J$=RIGHT$(R$(I),B)+LEFT$(R$(I),C):RETURN
4610 GOSUB 110:PRINT LEFT$("#################",M+2):RETURN
4910 Z=Z+1:IF Z=LEN(N$)+1 THEN READ N$:Z=1
4920 B=ASC(MID$(N$,Z,1)):A=ASC("A"):G=ASC("a"):H=ASC("0")
4930 W=63:IF B>=A AND B<A+26 THEN W=B-A
4940 IF B>=G AND B<G+26 THEN W=B-G+26
4950 IF B>=H AND B<H+10 THEN W=B-H+52
4960 IF B=ASC("+") THEN W=62
4970 RETURN
25000 DATA "CFBAKBCHABykADHABmVZBDICBkTlKEFDDCtSCEHADq6oWCFHAE"
25010 DATA "cpQvKJDICCFQtdEHBCUspqDEOBD/2gZ20O4fCEHBB2UpDDGNAA"
25020 DATA "4D6zp7p8nLmqJFGDBCmW6EEICDcwOXKAGGAFUVUNN0EKACsy1Y"
25030 DATA "q7CEHADWk2hELFKAEtpocFlqJAEHCDKsRVOEPCAeeWbNavRzTF"
25040 DATA "ICC1sGq9gCELACuBzaerBAFIDBkjpuqJNEJDAiYP3QBHJGCyTa"
25050 DATA "6tJE3PEAGHAAy08CdPAKNHAAg8f6AT+l7MFZ63Ux5+DAAHJBEy"
25060 DATA "wq1w+0rJ6AKLAJAg+39oWA9/GuNYu+HAAHKAAaRdTF2OVZd0F"
30000 REM leicht abgeaendert Th. Rademacher JOYCE-User-AG e.V.
30010 REM Zeilen 4040 und 4050 fuer 8-bit-Atari aktivieren
32000 REM Autor: Malcohol (Malcolm Tyrrell) auf GitHub 2020

--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 06.11.2023 um 14:12 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

012
06.11.2023, 08:20 Uhr
BICa5105

Da fehlt der BASIC Code von Zeile 0 bis 1000 !?
Hast du den eventuell noch ;-) ?

LG
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

013
06.11.2023, 11:01 Uhr
ThomasR

Avatar von ThomasR

Zitat:

ThomasR schrieb
(...)
Wie gewohnt muss zunächst der Bascoder geladen und gestartet werden, dann kann das Programm hinzugeladen werden.
(...)

Schau mal hier https://joyce.de/basicode/download/A5105.zip
oder hier https://www.iee.et.tu-dresden.de/~kc-club/DOWNLOAD/DISK702/BASICODE.BAS für den BIC
und hier https://joyce.de/basicode/download/disk151.zip für MSX.

Ich kann Dir auch gern Diskettenabbilder schicken (PN oder eMail).
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 06.11.2023 um 11:21 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

014
07.11.2023, 00:21 Uhr
Dirk mit KC-4

Zitat:

Da fehlt der BASIC Code von Zeile 0 bis 1000 !?
Hast du den eventuell noch ;-) ?

Das Programm hab ich hier gefunden. Der Quellcode in Posting #11 ist abgeändert für Amstrad JOYCE, der echte Quellcode sieht etwas anders aus:
https://github.com/Malcohol/BasicodeMazezaM

auf der Seite etwas runter scrollen, dann sieht man den Quellcode

jedoch ist auch dort ein Goto20 in Zeile 1000 und ein Gosusb 110 in Zeile 1920. Da fehlt also auf jeden Fall Quellcode..
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Dieser Beitrag wurde am 07.11.2023 um 00:21 Uhr von Dirk mit KC-4 editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

015
07.11.2023, 07:42 Uhr
ThomasR

Avatar von ThomasR

Ja und ja. Der Code ist leicht abgewandelt, ist am Programmende auch erwähnt) und das Programm muss noch mit den Bascoder-Routinen ergänzt werden, auch das steht im Beitrag. Das ist die Wirkungsweise von BasiCode: die Programme (ASCII) laufen auf vielen Computern, die Computer müssen jedoch dafür vorbereitet sein, also die Bascoder-Routinen, die computerspezifisch sind, müssen schon vorhanden sein.

Weil hier kein File-Upload möglich ist und ich die Textkästen nicht zu riesig werden lassen will, habe ich nur die universelle Hälfte hineingestellt.

In Beitrag 013 habe ich auf eine Quelle für den BIC-Bascoder und den MSX-Bascoder verwiesen, man kann auch das Programm aus 001 http://www.kc85emu.de/rt/kubusbic.asc herunterladen und von dort die Zeilen bis 950 ausschneiden und vor das Listing aus 011 setzen.

Immer noch zu ungeduldig? Hier wäre der (für dieses Programm gekürzte, aber ausreichende) Bascoder für den BIC:

Quellcode:

10 COLOR6,0,0:SCREEN3:COLOR0:CLS:SCREEN0,,,,,1:KEYOFF:WINDOW:CLS:MAXFILES=4:CLEAR200:IFPEEK(&HFEBA)=201THENMAXFILES=2
11 DEFINTA-Z:DIMCC(3):M=VAL("&H"+HEX$(PEEK(&HFBB6)+256*PEEK(&HFBB7))):IFPEEK(&HFEFD)=201THENCLEAR200,M-455:POKE&HFEFD,0:GOTO11
12 O$(1)="01e5c521**650e990605db98e60220fa3ee0d399db981f30fbeda220f7c1e1c9db98e60428fac50e983e49d399ed69ed61c1c9d5c50e985fdb98e60220fa3e30d399db98e60220faed59c1d1c9fd0d350d770cc40b1b0b7b0ae5095609d0085208da0769070000000000000000
13 O$(2)="6ddb98e62020fadb98e62028fa3e13d39d0e9cafcbbfd39e060821**65f5ed782f772310f9f1cbffd39e060821**65edb33c20e03e12d39dc9eb46235e23560405c81afe613807fe7f3003d620121318ef
14 O$(3)="bdf637f5060021fd1bcd**01cd**202bf1383bd9cde100cde100cde100cde400d8d923a847d97ad9ee80cd**33cb6cd928ebd92b1139b9e3e3e3e31b7ab320f7cd**2078cd**332a**65cd**20c9db98e60428fa3e4cd3993e02d3983e04d398d3983eb0d399d9cdea00d923db981f30fbdb99cb6c2803781806
15 O$(4)="36ee80f5a847f1d9f5cded00f1d9cb6c28e02a**65cd**20afc3e30b23237ed6153004c60c30fcfe603804d60c18f80601fe0c380504d60c18f7876f260011**4d195e235621200005280dcb3acb1bcb3ccb1d10f630011319afcd93005a556c3cfe0420f5c9
16 O$(5)="9b3e80d3a82110800e9c3e13d39dafd39e0608edb33c20f73ea0d3a83e12d39dc9
17 BLOAD"ZS.ZG",Z:LOCATE4,10,0:PRINT"A U G E N B L I C K":FORO=1TO5:I=VAL("&H"+MID$(O$(O),1,2)):IFO>=4THENI=I+256
18 FORT=3TOLEN(O$(O))STEP2:D$=MID$(O$(O),T,2):D=VAL("&H"+D$):IFD$="**"THENF=-1ELSEIFNOTFTHENPOKEM+I,D:I=I+1ELSEPOKEM+I,255AND(M+D):POKEM+I+1,255ANDINT((M+D)/256):I=I+2:F=0
19 NEXTT,O:CLS:GOTO1000
20 ONERRORGOTO951:IFA<200THENA=200
21 CLEARA:COLOR6,0,0:DEFSNGA-Z:DEFINTO:O=VAL("&H"+HEX$(PEEK(&HFBB6)+256*PEEK(&HFBB7))):DEFUSR=O+&H6D:DEFUSR1=O+&HA5:DEFUSR2=O+&HBD:DEFUSR3=O+&HBE:DEFUSR4=O+&H151:DEFUSR5=O+&H19B:SV=RND(-TIME):SV=7:ONSTOPGOSUB950:STOPON:OPEN"GRP:"AS1:ONERRORGOTO951
22 OX=230:OY=200:OW=45:OS=5
23 OZ=40:OQ=2048
24 O=USR(OQ):CC(0)=7:CC(1)=0
25 LOCATE,0:HO=OZ-1:VE=24:HG=OX:VG=OY:GOTO1010
100 SCREEN0:CC(2)=CC(0):CC(3)=CC(1):GOSUB152:WINDOW0,24,0,39:CLS:RETURN
110 LOCATEVEAND255ANDVE>-1,HOAND255ANDHO>-1:GOSUB152:RETURN
120 HO=POS(0):VE=CSRLIN:RETURN
150 GOSUB152:PRINT" ";:O$="  "+SR$+"  ":FORO=1TOLEN(O$):PRINTCHR$(128+ASC(MID$(O$,O)));:NEXT:PRINT" ";
151 COLORASC(MID$("094<:;>?",CC(2)+1,1))-48,ASC(MID$("01452367",CC(3)+1,1))-48:RETURN
152 COLORASC(MID$("094<:;>?",CC(0)+1,1))-48,ASC(MID$("01452367",CC(1)+1,1))-48:RETURN
200 IN=0:IN$=INKEY$:IFIN$=""THENRETURNELSEIN=ASC(IN$)
201 IFIN>27ANDIN<32THENIN=INXOR1
202 IFIN=8ORIN=127THENIN=127:IFPOS(0)THENIN$=CHR$(127)ELSEIN$=""
203 IFIN<>13ANDIN<28ORIN>127THENIN=-IN:IN$=CHR$(240)
204 IFIN>96ANDIN<127THENIN=IN-32:RETURNELSERETURN
210 TIME=0:LOCATE,,1
211 GOSUB200:IFIN=0THENIFTIME>18GOTO210ELSE211ELSELOCATE,,0
212 RETURN
220 IFHO<0ORVE<0ORHO>=OZORVE>24THENIN=0:RETURN
221 IN=VDEEK(VE*OZ+HO)AND127:IFIN<32THENIN=32
222 CN=0:IFIN>96ANDIN<127THENIN=IN-32:CN=32:RETURNELSERETURN
250 BEEP:RETURN
260 RV=RND(1):RETURN
270 FR=FRE(0)+FRE("")-50:RETURN
280 POKE&HFC09,0:POKE&HFA8D,FR:RETURN
950 CLEAR200:MAXFILES=1:GOSUB952:END
951 CLEAR200:MAXFILES=1:GOSUB952:O=INT(ERL/256):POKE&HF2E2,ERL-256*O:POKE&HF2E3,O:ERRORERR
952 COLOR6,0,0::DEFUSR=&H90:O=USR(0):O=USR5(0):KEYON:SCREEN0:WINDOW0,23,0,39:POKE&HFC09,0:POKE&HFA8D,0:CLS:RETURN

Der Spielspaß wird die Umstände lohnen!
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 07.11.2023 um 07:59 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

016
07.11.2023, 11:36 Uhr
Dirk mit KC-4

Zitat:

also die Bascoder-Routinen, die computerspezifisch sind, müssen schon vorhanden sein.

ach so, jetzt versteh ich das erst. Zeilen 1-999 sind je nach verwendeten Computer und ab Zeile 1000 geht das eigentliche Programm los.
Nicht schlecht die Idee, schade das man das nicht weiter geführt hat, auch für andere Programmiersprachen.
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

017
07.11.2023, 13:43 Uhr
ThomasR

Avatar von ThomasR

Fortsetzung hier:

https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=21350
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 08.11.2023 um 08:10 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

018
07.11.2023, 15:09 Uhr
Dirk mit KC-4

ich habe das gefunden:

"Ab September 1989 wird vom Rundfunk der DDR der Basicode verwendet. Zunächst erfolgt ein kleiner Lehrgang. Zu diesem Zeitpunkt kann ein begleitendes Material beim Rundfunk angefordert werden. Ferner wird es möglich sein, Bascoder für einige Rechner (wahrscheinlich auf einerSchallplatte) zu erhalten. Anfang 1990 wird der VEB Verlag Technik voraussichtlich ein umfangreiches Lehrbuch für Basicode anbieten."

Ist davon noch etwas rausgebracht worden? Hat da noch jemand was von?
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

019
07.11.2023, 15:25 Uhr
ThomasR

Avatar von ThomasR

Dieser Beitrag wurde am 08.11.2023 um 08:11 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

020
07.11.2023, 16:07 Uhr
Dirk mit KC-4

BasicodeLoader 2 für den KC84/4 hätt ich gerne.
BasicodeLoader 3 hab ich gefunden, aber da es ja auch reichlich Basicode Programme die nur unter Basiccode 2 laufen, hätt ich dann gerne den BasicodeLoader 2

(der Unterschied ist übrigens leicht zu erkennen, BasicodeLoader Version 3 hat ab Zeile 950 'Programm beenden', das gibts in der Version 2 nicht. Wenn wer BasicodeLoader Version 2 hat bitte im Basic-Quelltext hier reinkopieren)

Hier die BasicodeLoader Version 3, im Basic-Quelltext, ich musste etwas länger suchen, aber ich denke das die komplette und lauffähig:

1 REM --- BasicCodeLoader (Zeilen <1000) für den KC85/3/4 ---
3 REM BasiCode3 fuer SCP-Basic
4 REM Startpunkt des (Pseudo-)Zufallszahlengenerators
5 INPUT "Bitte geben Sie eine ganze Zahl zwischen -32768 und 32767 ein: ",RV
6 RV=FIX(RV):IF RV<-32768! THEN RV=-32768!
7 IF RV>32767 THEN RV=32767
8 RANDOMIZE(RV)
9 REM Groesse des Stringspeicherraums in A uebernehmen
10 GOTO 1000
19 REM Bildschirm und Variablen loeschen
20 PRINT CHR$(12);:CLEAR:HO=79:VE=23:GOTO 1010
100 PRINT CHR$(12);:RETURN:REM Bildschirm loeschen
109 REM Cursor an Position HO,VE setzen
110 PRINT CHR$(27);CHR$(128+VE);CHR$(128+HO);:RETURN
119 REM Ermitteln der Cursorposition
120 HO=POS(HO):RETURN
121 REM (ohne Rueckgriff auf Hardware-Individualitaet nur fuer horizontale Position loesbar)
149 REM auffaelliges Anzeigen von SR$
150 PRINT STRING$(3,160);:FOR OF%=1 TO LEN(SR$):PRINT CHR$(128+ASC(MID$(SR$,OF%,1)));:NEXT OF%:PRINT STRING$(3,160);:RETURN
199 REM Daten einer evtl. gedrueckten Taste werden (ohne Warten) uebernommen
200 IN=0:IN$=INKEY$:IF IN$<>"" THEN 211 ELSE RETURN
209 REM Warten auf Tastendruck und Uebernahme der Werte der gedrueckten Taste
210 GOSUB 200:IF IN$="" THEN 210
211 IN=ASC(IN$):RETURN
219 REM Lesen des Zeichens auf Position HO,VE
220 RETURN
221 REM (nur mit hardwarespezifischen Daten realisierbar)
249 REM Erzeugen eines kurzen Aufmerksamkeitstons
250 PRINT CHR$(7);:RETURN
259 REM Erzeugen einer Zufallsvariablen
260 RV=RND(ABS(100*RV)):RETURN
269 REM Ausfuehren von garbage collection, freier Speicher in FR
270 FR=FRE(""):RETURN
279 REM Sperren der Unterbrechungstaste
280 RETURN
281 REM (hardwareunabhaengig nicht realisierbar)
299 REM Umwandeln von Zahl in Zeichenkette, ohne fuehrendes Leerzeichen
300 SR$=STR$(SR):IF SR>=0 THEN SR$=MID$(SR$,2)
301 RETURN
309 REM formatierte Ausgabe von SR, CT Stellen, davon CN nach dem Dezimalpunkt
310 SR$=STR$(FIX(SR)):IF SR>=0 THEN SR$=MID$(SR$,2)
311 IF (SR<0 AND LEN(SR$)>CT-CN+1) OR (SR>=0 AND LEN(SR$)>CT-CN) THEN OP$="":SR$=STRING$(CT,42):GOTO 313
312 IF CN=0 THEN OP$="" ELSE OQ=INT(10^CN*(ABS(SR)-FIX(ABS(SR)))):OP$="."+MID$(STR$(OQ),2)
313 SR$=SR$+OP$:RETURN
329 REM Umwandlung von Kleinbuchstaben in SR$ in Grossbuchstaben
330 FOR OF%=1 TO LEN(SR$):IF ASC(MID$(SR$,OF%,1))>96 THEN GOSUB 332
331 NEXT OF%:RETURN
332 OSR%=ASC(MID$(SR$,OF%,1))-32:SR$=LEFT$(SR$,OF%-1)+CHR$(OSR%)+MID$(SR$,OF%+1):RETURN
349 REM SR$ wird an den Drucker geschickt (ohne Zeilenvorschub)
350 LPRINT SR$;:RETURN
359 REM Drucker in neue Zeile
360 LPRINT:RETURN
399 REM Erzeugung eines Tons entspr. Werten von SV, SD und SP
400 RETURN
401 REM (allenfalls hardwarespezifisch realisierbar)
449 REM Warten von max. SD*0.1 s auf Tastendruck, Rueckgabe der nicht verbrauchten Zeit in SD
450 OTIME=SD*5
451 GOSUB 200:IF IN<>0 THEN 453
452 OTIME=OTIME-1:IF OTIME>0 THEN 451
453 SD=INT(OTIME/5)
454 RETURN
455 REM (Faktor 5 in Zeile 450 UND 453 hardwarespezifisch anpassen)
499 REM Oeffnen einer Datei zum Lesen oder Schreiben
500 IF NF MOD 2=0 THEN OPEN "I",1,NF$:INPUT# 1,OBESTAND$:IN=0 ELSE PRINT NF$:OPEN "O",2,NF$:IN=0
501 RETURN
539 REM Uebergabe eines Strings aus der Datei in IN$
540 IN$=OBESTAND$:IF EOF THEN 543 ELSE INPUT# 1,OBESTAND$
541 IF OBESTAND$<>"" THEN OU$=MID$(OBESTAND$,1,1):IF ASC(OU$)=26 THEN OBESTAND$="":GOTO 543
542 IF NOT EOF THEN IN=0:GOTO 544
543 IN=1
544 RETURN
559 REM Schreiben von IN$ in die Datei
560 IN=1:PRINT# 2,SR$:IN=0:RETURN
579 REM Schliessen einer Datei
580 IF NF MOD 2=0 THEN CLOSE 1 ELSE PRINT# 2,CHR$(26):CLOSE 2 CLOSE 2
581 RETURN
599 REM Grafikmodus einschalten und Bildschirm loeschen
600 RETURN
601 REM (nur hardwarespezifisch realisierbar)
619 REM Grafikbetrieb: Punkt setzen
620 RETURN
621 REM (nur hardwarespezifisch realisierbar)
629 REM Grafikbetrieb: Linie zeichnen
630 RETURN
631 REM (nur hardwarespezifisch realisierbar)
649 REM Textausgabe im Grafikmodus
650 RETURN
651 REM (nur hardwarespezifisch realisierbar)
949 REM Beenden des BasiCode-Mode
950 PRINT CHR$(12):CLEAR:END
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

021
07.11.2023, 16:11 Uhr
Dirk mit KC-4

und das was ich geschrieben habe suche ich als .pdf Bücher, falls es die überhaupt gab, als dieses 'Lehrbuch' und den 'Lehrgang' und das 'begleitende Material':

"Ab September 1989 wird vom Rundfunk der DDR der Basicode verwendet. Zunächst erfolgt ein kleiner Lehrgang. Zu diesem Zeitpunkt kann ein begleitendes Material beim Rundfunk angefordert werden. Ferner wird es möglich sein, Bascoder für einige Rechner (wahrscheinlich auf einerSchallplatte) zu erhalten. Anfang 1990 wird der VEB Verlag Technik voraussichtlich ein umfangreiches Lehrbuch für Basicode anbieten."
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

022
07.11.2023, 16:33 Uhr
Dirk mit KC-4

Zitat:

3 REM BasiCode3 fuer SCP-Basic

sehe ich das falsch oder ist das nicht lauffähig unter CAOS KC85/3/4 ?

Dann suche ich entsprechend noch den BasicodeLoader V2 bzw. V3 lauffähig unter CAOS KC85/3/4
--
Ich kann 2 Dinge wirklich nur gut, zum einen war es die Fallschirmjägerei und zum anderen Computer. Fragt man, was ich nun besser kann, würden einige sagen das eine, andere würden das andere sagen. Aber im Grunde ist beides gleich: ein großes Abenteuer

Dieser Beitrag wurde am 07.11.2023 um 16:33 Uhr von Dirk mit KC-4 editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

023
07.11.2023, 17:34 Uhr
ThomasR

Avatar von ThomasR

Dieser Beitrag wurde am 08.11.2023 um 08:11 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

024
07.11.2023, 18:05 Uhr
Zwangsrentner

Zitat:
Das DDR-BasiCode-Buch (dem eine Vinyl-Single beilag) existiert meines Wissens noch nicht komplett als PDF.
Da könnte eventuell Ambrosius etwas haben.

Die Schallplatte gibt es als CD. Siehe http://www.mpm-kc85.de
grüsse aussem harz
--
I'm just a truckle, but I don't like to truckle >TIMOTHY TRUCKLE<

Dieser Beitrag wurde am 07.11.2023 um 18:06 Uhr von Zwangsrentner editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

025
07.11.2023, 18:24 Uhr
ThomasR

Avatar von ThomasR

Dieser Beitrag wurde am 08.11.2023 um 08:12 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

026
07.11.2023, 18:31 Uhr
BICa5105

.
Hm...
Also nicht falsch verstehen jetzt...aber wenn es rein um den BasiCode hier weiter gehen sollte wäre es vielleicht besser da ein eigenes Thema zu eröffnen.

Hier soll es ja eigentlich nur um neue Spiele für den BIC gehen ;-)

LG Cornelius
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

027
07.11.2023, 18:35 Uhr
ThomasR

Avatar von ThomasR

Ist richtig, vielleicht kann das ein Administrator aufsplitten?

Fortsetzung hier:

https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=21350
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 08.11.2023 um 08:12 Uhr von ThomasR editiert.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

028
07.11.2023, 21:08 Uhr
Rüdiger
Administrator

Zitat:

ThomasR schrieb
Ist richtig, vielleicht kann das ein Administrator aufsplitten?

Technisch unmöglich. Jeder Schreiber sollte selber wissen, was er tut!
--
Kernel panic: Out of swap space.

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

029
10.02.2024, 15:20 Uhr
BICa5105

So...es ist mal wieder soweit.

Ich habe wieder ein kleines Spiel für den BIC programmiert.

Diesmal ein Rennspiel. Also ein Geschicklichkeitsspiel.
Man muss eine kleine "Rennstrecke" abfahren, ohne gegen die "Strohballen" zu krachen.
Es gibt 7 Strecken. Die Streckenverläufe werden mit jeder neuen Strecke immer enger!
Man hat 4 Fahrzeuge pro Spiel.

Der Streckenverlauf/Fortschritt wird oben, durch eine sich gelb färbende Linie, angezeigt.
Die gefahrene Strecke oben rechts und verfügbare Fahrzeuge oben links.
Das Spiel hat auch ein paar Spielgeräusche...also Ton anstellen! :-)
Man kann es auch gut im JKCEMU spielen ;-)

Hier die Einzeldateien (starten mit AUTOEXEC.BAS) und die DSK Version (GOTEK,JKCEMU).

Viel Spaß :-)

https://www.dropbox.com/scl/fi/cdqqppdh3gxrjodzpkbeg/BICRaceDSK.zip?rlkey=euk4ni2edwm2hyidn59f736nb&dl=0
https://www.dropbox.com/scl/fi/xm2hvs7gmx8y2midhjgtp/BICRace_Dateien.zip?rlkey=5uhq6vnn164hppn86eh6wxrhz&dl=0

LG Cornelius
--
https://www.youtube.com/@robotronA5105

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

030
10.02.2024, 16:14 Uhr
Klaus

Hallo Cornelius,

Fleißg, fleißig

Danke.

Ich habe es gleich mal runter geladen.
Test mache ich im JKCEMU... der BIC ist momentan weg geräumt.

Viele Grüße,
Klaus

Profil || Private Nachricht || Suche

Zitatantwort || Editieren || Löschen

Seiten: -1- [ Technische Diskussionen ]