Robotrontechnik-Forum

Registrieren || Einloggen || Hilfe/FAQ || Suche || Mitglieder || Home || Statistik || Kalender || Admins Willkommen Gast! RSS

Robotrontechnik-Forum » Technische Diskussionen » KC compact Programme von Internet auf Kassette bekommen... » Themenansicht

Autor Thread - Seiten: -1-
000
24.06.2016, 14:24 Uhr
Kniffo



Hallo zusammen,

Es gibt ja auf der Seite vom KC-Club einen großen Software Fundus.
z.B. Spiele vom KC compact.
Diese bestehen idR. aus einer BAS Datei und mehreren BIN Dateien.

Aber wie bekomme ich das denn auf den Computer?
Die einzige Möglichkeit das einzulesen ist ja mein Kassettenlaufwerk....

Kniffo.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
001
24.06.2016, 22:45 Uhr
Besserwisser

Avatar von Besserwisser

Der KC Compact ist zu 99% kompatibel mit dem CPC 464, 664 und 6128.
Zum Emulieren der Hardware auf dem PC gibt es das Programm CPCEMU.
Damit ist auch der Dateitransfer zwischen PC und CPC (KCC) möglich.
Das passiert über ein selbst zu bauendes Kabel,
mit dem die beiden Druckerschnittstellen verbunden werden.
Du must nur ein kurzes Programm in den KCC einmeiseln,
womit man die anderen notwendigen Dateien auf den KCC transportieren kann.

http://benchmarko.de/cpcemu/index.html (siehe DOKU Absatz 5)

Damit bekommst du die Software vom Forum über den PC auf den KCC
und kannst sie dann auf Kassetten speichern.

Hier findest du auch noch Interessantes:

http://www.cpcwiki.eu/index.php/KC_Compact

Dieser Beitrag wurde am 25.06.2016 um 00:13 Uhr von Besserwisser editiert.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
002
25.06.2016, 09:13 Uhr
PC-Opa



Hallo Kniffo,

bei Ulrich auf der Homepage findest Du auch noch eine kleine Softwaresammlung.

http://www.sax.de/~zander/index2h.html

Da gibt es auch noch Infos und Dokumentationen zum KCC.

Gruß Wolfgang
--
Gruß Wolfgang
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
003
06.04.2023, 14:00 Uhr
ThomasR

Avatar von ThomasR

Rubik's Cube in Farbe

Schon 1985 schrieb ein belgischer Computer-Enthusiast ein Programm, das beim Lösen des Zauberwürfels helfen kann. Es ist in der Ur-Form hier http://robhagemans.github.io/basicode/basicode/Best_of_Basicode_2/B09_Kubus_van_Rubik.bc2 zu finden, wo es auch gleich ausprobiert werden kann. Die Bedienung fand ich zu unhandlich, besonders wegen der Abkürzungen niederländischer Worte für die Farben und Ebenen - A wie achtern O für unten, B für oben.

Deswegen habe ich vor ein paar Jahren die Bedienung auf deutsch umgeschrieben: siehe https://joyce.de/basicode/diesunddas/kubus.htm .



Als Rentner habe ich nun endlich die Zeit gefunden, umzusetzen, was mir schon lange vorschwebte: die Darstellung auf Farbe umzustellen.

Ich stelle es hier als ready-to-use-Programm vor Frank bietet freundlicherweise den Download von seiner Website an: http://www.kc85emu.de/rt/kubuskcc.bas . Eine KC85-Version gibt es hier: https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=20758 .

Eigentlich setzt es sich aus drei Bestandteilen zusammen, dem Bascoder, dessen Farberweiterung und zu guter Letzt dem Programm von Jan Broeckx. Das erwähne ich, um mich nicht mit fremden Fdern zu schmücken.

BasiCode, das Computer-Esperanto aus den achtziger Jahren hat sich auch in Großbritannien nie sehr stark verbreitet. Der BBC Acorn ist wohl ziemlich der einzige Computer, für den es dort auch Version 3 gab. Diesen Code von Peter Maathuis nahm 2005 Victor Reijs als Grundlage, um eine Version zu schreiben, die unter dem BBC Basic for Windows läuft, das eins zu eins auch unter CP/M auf dem Amstrad CPC nutzbar ist - und damit auch auf dem KC compact.



Wir nutzen jedoch das Locomotive-Basic. Hardwarebedingt stellen beide Basics in MODE 1 leider nur vier Farben zur Verfügung (siehe Ausgabe des Programms FARBTEST). Deswegen gab es noch einige Nacharbeit, das Programm in MODE 0 nutzbar zu machen, dort gibt es mehr als genug Farben für die sechs Seiten des Würfels. Nur für die größeren Textausgaben wird in MODE 1 gewechselt.



Das Programm (das durchgängig mit Großbuchstaben bedient wird) bietet drei Möglichkeiten:

- Von einem "aufgeräumten" Würfel ausgehend kann man (Grund-Achsen immer beibehalten, nicht den kompletten Würfel drehen!) die vordere, hintere, linke, rechte obere bzw. untere Ebene drehen und schließlich vom Programm wieder in Ordnung bringen lassen.

In manchen Fällen resigniert das Programm beim Lösen einer selbst eingegebenen Stellung, aber viele Lösungen schafft es tatsächlich. Natürlich darf man keine Kombinationen eingeben, die am realen Zauberwürfel nur durch Herausnehmen und verkehrt-wieder-Einsetzen eines Eck- oder Kantenteils (oder Wechseln von Klebeetiketten) erzeugt werden können. Hier entsteht eine Fehlermeldung, denn der Autor hat verschiedene Kniffe angewendet, um den komplexen Algorithmus im verfügbaren RAM unterzubringen. Einer davon ist, für nicht auftretende Fälle eine nicht existiereende Zeilennummer zu verwenden:


Quellcode:
...
4530 IF A>6 THEN 4560
4540 ON A GOSUB 1,1,10450,1,10860,10870
4550 GOTO 4570
...



Das hat mich lange irritiert, ich hielt das für Übertragungsfehler und dachte, das Programm sei nicht lauffähig.

- Man kann seinen (verdrehten) realen Würfel Teilfläche für Teilfläche ins Programm eingeben und dann das Programm lösen lassen.

- Zu guter Letzt gibt es noch eine Demonstration von über einem Dutzend regelmäßigen Mustern nebst jeweils einer Anleitung, wie dieses Muster aus der Grundstellung zu erreichen ist.


--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 06.04.2023 um 14:04 Uhr von ThomasR editiert.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
004
06.04.2023, 18:56 Uhr
robbi
Default Group and Edit
Avatar von robbi

@002
Genauer:
http://www.sax.de/~zander/kcc/kcc_sw.html
Die Programme habe ich als WAV-Dateien vorliegen. Das ist wohl die unkomplizierteste Methode für die meisten Nutzer.
--
Schreib wie du quatschst, dann schreibst du schlecht.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
005
17.06.2023, 15:36 Uhr
ThomasR

Avatar von ThomasR

Das farbige Zauberwürfel-Programm

https://www.robotrontechnik.de/html/forum/thwb/showtopic.php?threadid=20758

enthält einen Fehler, auf den mich Frank aufmerksam machte.


Quellcode:
...
5930 IF a(7,6)=a(6,7) THEN 5360
5940 IF a(6,6)=a(8,5) THEN a$="=-H-U-R-HR-V-RHRUH-UV": REM   <----  erstes Zeichen von a$ verkehrt!
5950 IF a(6,6)=a(8,5) THEN GOSUB 10540:GOTO 5890
...



muss heißen


Quellcode:
...
5930 IF a(7,6)=a(6,7) THEN 5360
5940 IF a(6,6)=a(8,5) THEN a$="U-H-U-R-HR-V-RHRUH-UV"
5950 IF a(6,6)=a(8,5) THEN GOSUB 10540:GOTO 5890
...



Das ist mir selbst 2007 unterlaufen, als ich Leerzeichen nach den Schlüsselwörtern einfügte und dergleichen, um das Programm in ASCII-Form auch auf anderen Wegen übertragen zu können. Vele Computerbasics "pochen" auf diese Leerzeichen.

Nun sollten alle Eingaben aus Menüpunkt A und alle legalen Eingaben aus Menüpunkt B zu einer erfolgreichen Lösung führen.

Auf Franks Homepage http://www.kc85emu.de/rt/kubuskcc.bas gilt das ebenso, vielleicht hat er es zwischenzeitlich auch geändert, einfach Zeile 5940 darauf checken.
--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
006
05.11.2023, 21:03 Uhr
ThomasR

Avatar von ThomasR

Korrektur zu OTHELLOC

Schon vom Ursprungsprogramm her war ein Fehler enthalten: manchmal wurden die kleinen Kästchen mit der Anzeige der Steine-Anzahl unvollständig gelöscht und dadurch im weiteren Verlauf verwaschen angezeigt.

Frank kam der Ursache auf die Spur und mailte mir:


Die Grafikfehler bei der Anzahl der Steine habe ich gefunden. Sie treten scheinbar nur bei Level 2 auf.
Die Ursache war, dass die Variablen CO und C2 auch für die Berechnung des nächsten Zuges missbraucht werden.


Als Abhilfe führte er erfolgreich die neuen Variablen CL und CR ein. Im Programm müssen folgende Zeilen korrigiert werden:

1020 NM=0:WU=0:CO=0:C2=0:CL=0:CR=0:REM DIM CC(2)

3190 HO=.03:VE=.8:CN=1:SR=CL:GOSUB 300:GOSUB 650

3200 HO=.91:SR=CR:GOSUB 300:GOSUB 650:CN=0

3230 CL=CO:SR=CO:GOSUB 300:CC(0)=4:GOSUB 650

3250 CR=C2:SR=C2:GOSUB 300:CC(0)=2:GOSUB 650:CC(0)=7:RETURN

--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 05.11.2023 um 21:58 Uhr von ThomasR editiert.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
007
05.11.2023, 21:03 Uhr
ThomasR

Avatar von ThomasR

Malcolm Tyrrell schrieb 2003 für den ZX Spectrum MazezaM, ein schön kniffliges Programm, halb Sokoban, halb Labyrinth:



Inzwischen gibt es dieses Knobelspiel auf einigen anderen Computern wie auch für den Windows-PC:



2020 schrieb der Autor eine Version für BasiCode, die damit, den entsprechenden Bascoder vorausgesetzt, auch auf dem CPC und KCc läuft:



Die Version ist zwar nicht so farbenfroh wie die beiden vorgenannten Versionen, aber die Herausforderung der Rätsel ist unverändert. Obendrein bietet sie den Vorteil, dass die Zahl der Versuche nicht begrenzt ist und man auch einfach in den nächsten Level springen kann. Aufgabe ist, das Labyrinth zu durchqueren, wofür jeweils eine komplette Zeile von Hindernissen verschoben werden kann. Die Bedienung erfolgt mit den Cursortasten oder mit den Klein- oder Großbuchstaben i, j, k, l. Wie gewohnt muss zunächst der Bascoder geladen und gestartet werden, dann kann das Programm hinzugeladen werden.

Viel Spaß damit!


Quellcode:
1000 A=194:GOTO 20:REM *** MAZEZAM ***
1010 DIM R$(11):DIM Y(11):HO=14:VE=14
1310 HO=HO+1:R=HO:GOSUB 110:GOSUB 120:IF R=HO THEN 1310
1610 VE=VE+1:S=VE:GOSUB 110:GOSUB 120:IF VE=S THEN 1610
1910 GOSUB 100:VE=6:HO=(R-7)/2:GOSUB 110:PRINT"MazezaM":VE=S-6
1920 HO=0:GOSUB 110:PRINT" MOVE ijkl":PRINT"RETRY r"
1930 PRINT" SKIP s":PRINT" QUIT q":GOSUB 210
1940 IF IN<>81 THEN 1960
1950 GOTO 950
1960 RESTORE:Z=0:N$="":T=0
2210 GOSUB 250:T=T+1:IF T=31 THEN 1910
2220 GOSUB 4910:N=W:GOSUB 4910:M=W:GOSUB 4910:P=W:GOSUB 4910:Q=W
2230 F=0:FOR C=0 TO N-1:R$(C)="":Y(C)=0:FOR D=0 TO M-1:A$="="
2240 IF F=0 THEN GOSUB 4910:F=6
2250 F=F-1:G=INT(W/2)*2:IF W=G THEN A$=" "
2260 R$(C)=R$(C)+A$:W=G/2:NEXT D:NEXT C:U=INT((R-M)/2)
2270 V=INT((S-N)/2)
2510 GOSUB 100
2810 VE=V-1:HO=U-1:W=P:X=0:GOSUB 4610:FOR I=0 TO N-1:Y(I)=0
2820 VE=VE+1:GOSUB 110:A$="#":B$=A$:IF I=P THEN A$=">"
2830 IF I=Q THEN B$=">"
2840 PRINT A$;:GOSUB 4010:PRINT B$:NEXT I:VE=VE+1:GOSUB 4610
2850 HO=HO+1
3110 GOSUB 210:D=W:E=X:IF (IN=73 OR IN=31) AND W>0 THEN D=W-1
3120 IF (IN=75 OR IN=30) AND W<N-1 THEN D=W+1
3130 IF (IN=74 OR IN=28) AND X>0 THEN E=X-1:F=1
3140 IF (IN=76 OR IN=29) AND X<M-1 THEN E=X+1:F=M
3150 IF (IN=76 OR IN=29) AND W=Q AND X=M-1 OR IN=83 THEN 2210
3160 IF IN=81 THEN 1910
3170 IF IN=82 THEN 2810
3180 I=D:GOSUB 4310
3190 IF MID$(J$,E+1,1)=" " THEN I=W:W=D:X=E:GOSUB 3710:GOTO 3410
3200 IF X<>E AND MID$(J$,F,1)=" " THEN Y(W)=Y(W)+E-X:X=E
3410 I=W:GOSUB 3710:GOTO 3110
3710 VE=V+I:GOSUB 110
4010 GOSUB 4310:IF I<>W THEN PRINT J$;:RETURN
4020 IF X>0 THEN PRINT LEFT$(J$,X);
4030 PRINT "@";:IF X<M-1 THEN PRINT RIGHT$(J$,M-X-1);
4040 REM B$="#":IF I=Q THEN B$=">"
4050 REM PRINT B$
4060 RETURN
4310 IF Y(I)=0 THEN J$=R$(I):RETURN
4320 IF Y(I)>0 THEN B=Y(I):C=M-B
4330 IF Y(I)<0 THEN C=-Y(I):B=M-C
4340 J$=RIGHT$(R$(I),B)+LEFT$(R$(I),C):RETURN
4610 GOSUB 110:PRINT LEFT$("#################",M+2):RETURN
4910 Z=Z+1:IF Z=LEN(N$)+1 THEN READ N$:Z=1
4920 B=ASC(MID$(N$,Z,1)):A=ASC("A"):G=ASC("a"):H=ASC("0")
4930 W=63:IF B>=A AND B<A+26 THEN W=B-A
4940 IF B>=G AND B<G+26 THEN W=B-G+26
4950 IF B>=H AND B<H+10 THEN W=B-H+52
4960 IF B=ASC("+") THEN W=62
4970 RETURN
25000 DATA "CFBAKBCHABykADHABmVZBDICBkTlKEFDDCtSCEHADq6oWCFHAE"
25010 DATA "cpQvKJDICCFQtdEHBCUspqDEOBD/2gZ20O4fCEHBB2UpDDGNAA"
25020 DATA "4D6zp7p8nLmqJFGDBCmW6EEICDcwOXKAGGAFUVUNN0EKACsy1Y"
25030 DATA "q7CEHADWk2hELFKAEtpocFlqJAEHCDKsRVOEPCAeeWbNavRzTF"
25040 DATA "ICC1sGq9gCELACuBzaerBAFIDBkjpuqJNEJDAiYP3QBHJGCyTa"
25050 DATA "6tJE3PEAGHAAy08CdPAKNHAAg8f6AT+l7MFZ63Ux5+DAAHJBEy"
25060 DATA "wq1w+0rJ6AKLAJAg+39oWA9/GuNYu+HAAHKAAaRdTF2OVZd0F"
30000 REM leicht abgeaendert Th. Rademacher JOYCE-User-AG e.V.
30010 REM Zeilen 4040 und 4050 fuer 8-bit-Atari aktivieren
32000 REM Autor: Malcohol (Malcolm Tyrrell) auf GitHub 2020


--
Tot wie ein Dodo?
viele Informationen zu BasiCode auf basicode.de

Cu via komputilo povas Esperanto?
Jes, BasiCode!

Dieser Beitrag wurde am 06.11.2023 um 14:04 Uhr von ThomasR editiert.
Seitenanfang Seitenende
Profil || Private Nachricht || Suche Zitatantwort || Editieren || Löschen
Seiten: -1-     [ Technische Diskussionen ]  



Robotrontechnik-Forum

powered by ThWboard 3 Beta 2.84-php5
© by Paul Baecher & Felix Gonschorek